blob: 9e251393534c31caf81770abfa6e0e5d30d17eb6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# $Id: PKGBUILD 220451 2014-08-20 20:07:07Z heftig $
# Maintainer (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>
pkgname=evince
pkgver=3.12.2
pkgrel=1.parabola1
pkgdesc="Document viewer (PDF, Postscript, djvu, tiff, dvi, XPS, SyncTex support with gedit, comics books (cbr,cbz,cb7 and cbt)), with libarchive support"
url="https://wiki.gnome.org/Apps/Evince"
arch=(i686 x86_64 mips64el)
license=(GPL)
replaces=(${pkgname}-libre)
conflicts=(${pkgname}-libre)
depends=(gtk3 libgxps libspectre gsfonts poppler-glib djvulibre gnome-icon-theme t1lib libsecret desktop-file-utils dconf gsettings-desktop-schemas)
makedepends=(itstool libnautilus-extension texlive-bin intltool gobject-introspection docbook-xsl python)
optdepends=('texlive-bin: DVI support'
'gvfs: bookmark support and session saving'
'p7zip: cbz and cb7 compressed comic books'
'tar: cbt compressed comic books'
'libarchive: cbr compressed comic books')
groups=(gnome)
install=evince.install
options=('!emptydirs')
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver:0:4}/$pkgname-$pkgver.tar.xz
libarchive.patch)
sha256sums=('30c243bbfde56338c25a39003b4848143be42157177e2163a368f14139909f7d'
'023f01f40c5efb8bf245d97067b3ef1da74f96a0bc53e53eb3d990d6c29b9e5e')
prepare() {
cd $pkgname-$pkgver
patch -Np1 -i ../libarchive.patch
}
build() {
cd $pkgname-$pkgver
./configure --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var --libexecdir=/usr/lib/evince \
--disable-static --enable-nautilus \
--enable-pdf --enable-tiff \
--enable-djvu --enable-dvi \
--enable-t1lib --enable-comics \
--disable-scrollkeeper --disable-schemas-compile \
--enable-introspection
make
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
}
|
