blob: 1713b844cd997f1a67f3a311a0232dedc14dbe74 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# $Id: PKGBUILD 288002 2017-02-03 23:55:29Z heftig $
# Maintainer (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>
pkgname=epiphany
pkgver=3.22.6
pkgrel=1.parabola1
pkgdesc="A GNOME web browser based on the WebKit rendering engine, with DuckDuckGo HTML support"
url="https://wiki.gnome.org/Apps/Web"
arch=(i686 x86_64 armv7h)
license=(GPL)
depends=(webkit2gtk gcr gnome-desktop)
makedepends=(intltool itstool docbook-xml startup-notification lsb-release
gobject-introspection yelp-tools autoconf-archive appstream-glib git)
groups=(gnome)
replaces=(${pkgname}-libre)
conflicts=(${pkgname}-libre)
_commit=dfeedecc5c92980e0c6cf57f297063503bf0b013 # tags/3.22.6^0
source=("git+https://git.gnome.org/browse/epiphany#commit=$_commit"
"git+https://git.gnome.org/browse/libgd"
pluginsdir.diff)
sha256sums=('SKIP'
'SKIP'
'42a7b820fd659fee8508a9b9a57e385c658b3b312c7a8f9456078223e4d78f22')
pkgver() {
cd $pkgname
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd $pkgname
patch -Np1 -i ../pluginsdir.diff
git submodule init
git config --local submodule.libgd.url "$srcdir/libgd"
git submodule update
NOCONFIGURE=1 ./autogen.sh
# Replace DuckDuckGo to DuckDuckGo HTML
sed -i 's|duckduckgo[.]com|duckduckgo.com/html|g' $(grep -rlI 'duckduckgo[.]com')
# Replace Google support to DuckDuckGo HTML
sed -i 's|http://www[.]google[.]com/search?q=%s[&]ie=UTF-8[&]oe=UTF-8|https://duckduckgo.com/html/?q=search|g' $(grep -rlI 'http://www[.]google[.]com/search?q=%s&ie=UTF-8&oe=UTF-8')
sed -i '\|a quoted string should be searched|d' $(grep -rlI 'a quoted string should be searched')
sed -i 's|http://www[.]google[.]com/search?q=%s[&]amp;ie=UTF-8[&]amp;oe=UTF-8|https://duckduckgo.com/html/?q=%s|g' $(grep -rlI 'http://www[.]google[.]com/search')
sed -i 's|http://www[.]google[.]com|https://duckduckgo.com/html|g' $(grep -rlI 'google[.]com')
sed -i 's|http://google[.]com|https://duckduckgo.com/html|g' $(grep -rlI 'google[.]com')
sed -i 's|mail[.]google[.]com|mail.com|g' $(grep -rlI 'mail[.]google[.]com')
sed -i 's|google[.]com|duckduckgo.com/html|g' $(grep -rlI 'google[.]com')
}
build() {
cd $pkgname
./configure --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var --libexecdir=/usr/lib/$pkgname
# https://bugzilla.gnome.org/show_bug.cgi?id=655517
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
cd $pkgname
make DESTDIR="$pkgdir" install
}
|
