blob: 3251ae9a2cda309cc56c23fce638c6ec8253733a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Maintainer (Arch): Jelle van der Waa <jelle@vdwaa.nl>
# Maintainer (Arch): Daniel Wallace <danielwallace at gtmanfred dot com>
# Contributor (Arch): Giovanni Scafora <giovanni@archlinux.org>
# Contributor (Arch): Petrov Roman <nwhisper@gmail.com>
# Contributor (Arch): Andrea Fagiani <andfagiani _at_ gmail dot com>
# Contributor (Arch): Larry Hajali <larryhaja@gmail.com>
# Contributor (Arch): Eli Schwartz <eschwartz93@gmail.com>
# Contributor: André Silva <emulatorman@riseup.net>
# Contributor: Márcio Silva <coadde@riseup.net>
# Contributor: David P.<megver83@parabola.nu>
# Maintainer: Jesús E.<heckyel@parabola.nu>
pkgname=calibre
pkgver=3.1.1
_commit=85222be3542e80b5917863754d7cd333bc3472f2
pkgrel=1.parabola1
pkgdesc="Ebook management application, without nonfree decompression engine for RAR archives"
arch=('x86_64' 'i686' 'armv7h')
url="https://calibre-ebook.com/"
license=('GPL3')
depends=('python2-six' 'python2-dateutil' 'python2-cssutils' 'python2-cherrypy'
'python2-mechanize' 'podofo' 'libwmf'
'chmlib' 'python2-lxml' 'libusbx'
'python2-pillow' 'shared-mime-info' 'python2-dnspython'
'python2-pyqt5' 'python2-psutil' 'icu' 'libmtp' 'python2-dbus'
'python2-netifaces' 'python2-cssselect' 'python2-apsw' 'qt5-webkit'
'qt5-svg' 'python2-chardet' 'python2-regex' 'python2-pygments' 'mtdev'
'desktop-file-utils' 'gtk-update-icon-cache' 'optipng' 'udisks2')
makedepends=('qt5-x11extras' 'xdg-utils')
optdepends=('ipython2: to use calibre-debug'
'poppler: required for converting pdf to html')
replaces=($pkgname-libre)
conflicts=($pkgname-libre)
source=("$pkgname-$pkgver.tar.gz::https://gitlab.com/Megver83/calibre/repository/archive.tar.gz?ref=$pkgver"
"$pkgname-$pkgver.tar.gz.sig::https://gitlab.com/Megver83/calibre/raw/signatures/$pkgname-$pkgver-${_commit}.tar.gz.sig")
sha512sums=('6f1b32cdcdc7203686716bea6a3b976efee5bca94aa7a89c1f84afa87a5f0b9174aea4cadb220b09d9a4ec520d082693e080c0a33ef6b4abfce6cc5642379214'
'SKIP')
validpgpkeys=('6DB9C4B4F0D8C0DC432CF6E4227CA7C556B2BA78' # David P.
'916FFBC76D2E641BA416BA53364F4E1483446AC5' # Jesús E.
)
build() {
mv "$pkgname-$pkgver-${_commit}" "$pkgname-$pkgver"
cd "${pkgname}-${pkgver}"
LANG='en_US.UTF-8' python2 setup.py build
LANG='en_US.UTF-8' python2 setup.py gui
}
package() {
cd "${pkgname}-${pkgver}"
install -d "${pkgdir}/usr/share/zsh/site-functions" \
"${pkgdir}"/usr/share/{applications,desktop-directories,icons/hicolor}
install -Dm644 resources/calibre-mimetypes.xml \
"${pkgdir}/usr/share/mime/packages/calibre-mimetypes.xml"
XDG_DATA_DIRS="${pkgdir}/usr/share" LANG='en_US.UTF-8' \
python2 setup.py install --staging-root="${pkgdir}/usr" --prefix=/usr
# Compiling bytecode FS#33392
python2 -m compileall "${pkgdir}/usr/lib/calibre/"
python2 -O -m compileall "${pkgdir}/usr/lib/calibre/"
}
|
