blob: 8d6e44bac7c2da9ec1a7e0f474f6326ef0b53768 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# $Id: PKGBUILD 287876 2017-02-01 15:04:41Z bpiotrowski $
# Maintainer (Arch): Dave Reisner <dreisner@archlinux.org>
# Contributor (Arch): Gaetan Bisson <bisson@archlinux.org>
# Contributor (Arch): Daniel J Griffiths <ghost1227@archlinux.us>
# Contributor (Arch): Jeff 'codemac' Mickey <jeff@archlinux.org>
# Contributor (Arch): simo <simo@archlinux.org>
# Contributor (Arch): FUBAR <mrfubar@gmail.com>
# Maintainer: Márcio Silva <coadde@parabola.nu>
pkgname=bitlbee
pkgver=3.5.1
pkgrel=1.parabola1
pkgdesc='Brings instant messaging (XMPP, MSN, Yahoo!, AIM, ICQ, Twitter) to IRC, without nonfree Skype support'
url='http://www.bitlbee.org/'
license=('GPL')
arch=('i686' 'x86_64' 'armv7h')
depends=('gnutls' 'glib2')
makedepends=('python' 'libotr')
optdepends=('libotr: for OTR encryption support')
replaces=("${pkgname}-libre" "${pkgname}-parabola")
conflicts=("${pkgname}-libre" "${pkgname}-parabola")
source=("http://get.bitlbee.org/src/$pkgname-$pkgver.tar.gz"
'bitlbee.tmpfiles')
sha1sums=('de0767facdb7729253ae4d6ef6e3637ebd54939a'
'3695ed2fe22436c4d0fc3ead829f7d1f89bc491c')
backup=('etc/bitlbee/bitlbee.conf'
'etc/bitlbee/motd.txt')
install=bitlbee.install
build() {
cd "$pkgname-$pkgver"
./configure \
--prefix=/usr \
--etcdir=/etc/bitlbee \
--sbindir=/usr/bin \
--pidfile=/run/bitlbee/bitlbee.pid \
--ipcsocket=/run/bitlbee/bitlbee.sock \
--systemdsystemunitdir=/usr/lib/systemd/system \
--ssl=gnutls \
--strip=0 \
--otr=plugin \
--skype=0
make
}
package() {
make -C "$pkgname-$pkgver" DESTDIR="$pkgdir" install{,-etc,-dev,-systemd}
install -o65 -g65 -dm770 "$pkgdir/var/lib/bitlbee"
install -Dm644 "$srcdir/bitlbee.tmpfiles" "$pkgdir/usr/lib/tmpfiles.d/bitlbee.conf"
}
|
