blob: 82cd39b12c052b9d995c4d42d6c651ea7bf8f582 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer (Arch): Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor (Arch): M0Rf30
# Contributor (Arch): Samsagax <samsagax@gmail.com>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Contributor (Hyperbola): Márcio Silva <coadde@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
_basekernel=4.17
_archrel=152
_parabolarel=1
pkgbase=bbswitch
pkgname=(bbswitch bbswitch-dkms)
pkgver=0.8
pkgrel=${_archrel}.parabola${_parabolarel}.basekernel${_basekernel}
pkgdesc="Kernel module allowing to switch dedicated graphics card on Optimus laptops (built for the linux-libre kernel package)"
arch=('i686' 'x86_64')
url="http://github.com/Bumblebee-Project/${pkgbase}"
license=('GPL')
# Generic (you shouldn't have to modify any of these variables)
_toohigh=$(IFS=. read a b <<<$_basekernel; echo $a.$((b+1)))
makedepends=("linux-libre-headers>=${_basekernel}" "linux-libre-headers<${_toohigh}" "linux-libre>=${_basekernel}" "linux-libre<${_toohigh}")
makedepends+=('libelf')
_extramodules=extramodules-${_basekernel}
source=("${pkgbase}-${pkgver}.tar.gz::https://github.com/Bumblebee-Project/bbswitch/archive/v${pkgver}.tar.gz")
sha256sums=('76cabd3f734fb4fe6ebfe3ec9814138d0d6f47d47238521ecbd6a986b60d1477')
build() {
cd "${pkgbase}-${pkgver}"
_kernver="$(cat /usr/lib/modules/${_extramodules}/version)"
make KDIR=/lib/modules/${_kernver}/build
}
package_bbswitch() {
depends=("linux-libre>=${_basekernel}" "linux-libre<${_toohigh}")
replaces=("${pkgbase}-libre" "${pkgbase}-parabola")
conflicts=("${pkgbase}-libre" "${pkgbase}-parabola")
cd "${pkgbase}-${pkgver}"
install -Dt "${pkgdir}/usr/lib/modules/${_extramodules}" -m644 *.ko
find "${pkgdir}" -name '*.ko' -exec xz {} +
}
package_bbswitch-dkms() {
depends=('dkms')
conflicts=('bbswitch')
provides=('bbswitch')
cd "${pkgbase}-${pkgver}"
install -Dt "${pkgdir}/usr/src/${pkgbase}-${pkgver}" -m644 Makefile bbswitch.c dkms/dkms.conf
}
|
