blob: 5fd0286987c1170c52ee37bc6d0435f5f7a709d9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
# Maintainer (Arch): Levente Polyak <anthraxx[at]archlinux[dot]org>
# Maintainer (Arch): Eric Bélanger <eric@archlinux.org>
# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# parabola changes and rationale:
# - removed faac support
pkgbase=avidemux
pkgname=('avidemux-cli' 'avidemux-qt')
pkgver=2.7.0
pkgrel=4.parabola1
pkgdesc='Graphical tool to edit video (filter/re-encode/split), without nonfree faac support'
url='http://fixounet.free.fr/avidemux/'
arch=('x86_64' 'i686' 'armv7h')
license=('GPL2')
makedepends=('cmake' 'libxslt' 'qt5-base' 'jack' 'libvorbis' 'libxv' 'opus' 'desktop-file-utils'
'alsa-lib' 'lame' 'xvidcore' 'faad2' 'x264' 'libx264' 'x265' 'libsamplerate'
'opencore-amr' 'yasm' 'mesa' 'libvpx' 'libpulse' 'libva' 'intltool' 'sqlite'
'libvdpau' 'libdca' 'fribidi' 'glu' 'qt5-tools')
options=('!emptydirs')
source=(https://downloads.sourceforge.net/avidemux/avidemux_${pkgver}.tar.gz)
sha256sums=('fe1d6b794c0d94922428ff84a931264a90c39a5ffe965e03ab7ae0ce71a2c4ad')
sha512sums=('7c92213d3bd2849dbdb5a1aff2acd6da231fd76c561b756fbf4a1d5a41e9705d609d7a35b6ca6b77ceb3bf5138f861cd24ed16d8fcec4fd713f09a2ff07e9015')
prepare() {
cd ${pkgbase}_${pkgver}
sed -i 's|../avidemux/qt4|../avidemux/qt4 -DLRELEASE_EXECUTABLE=/usr/bin/lrelease-qt5|' bootStrap.bash
cp avidemux2.desktop avidemux-qt.desktop
sed -ri 's|(Name=).*|\1avidemux (Qt)|' avidemux-qt.desktop
sed -ri 's|(Exec=).*|\1avidemux3_qt5|' avidemux-qt.desktop
}
build() {
cd ${pkgbase}_${pkgver}
bash bootStrap.bash --with-core --with-cli --with-plugins
}
package_avidemux-cli() {
depends=('libxml2' 'fontconfig' 'libvpx' 'libva' 'sqlite')
optdepends=('lame: for the corresponding audio encoder plugin'
'faad2: for the corresponding audio decoder plugin'
'opus: for the corresponding audio decoder plugin'
'opencore-amr: for the corresponding audio decoder plugin'
'jack: for the corresponding audio device plugin'
'libpulse: for the corresponding audio device plugin'
'x264: for the corresponding video encoder plugin'
'libx264: for the corresponding video encoder plugin'
'x265: for the corresponding video encoder plugin'
'xvidcore: for the corresponding video encoder plugin'
'qt5-base: for the QtScript scripting support'
'libdca: for the corresponding audio decoder plugin'
'fribidi: for the corresponding video filter plugin')
cd ${pkgbase}_${pkgver}
make -C buildCli DESTDIR="${pkgdir}" install
make -C buildCore DESTDIR="${pkgdir}" install
make -C buildPluginsCLI DESTDIR="${pkgdir}" install
make -C buildPluginsCommon DESTDIR="${pkgdir}" install
install -Dm 644 avidemux_icon.png "${pkgdir}/usr/share/pixmaps/avidemux.png"
install -Dm 644 man/avidemux.1 -t "${pkgdir}/usr/share/man/man1"
}
package_avidemux-qt() {
pkgdesc='Graphical tool to edit video (filter/re-encode/split) - Qt GUI, without nonfree faac support'
depends=("avidemux-cli=${pkgver}" 'qt5-base' 'x264' 'x265' 'libx264' 'glu' 'libxv' 'desktop-file-utils')
replaces=('avidemux-gtk')
cd ${pkgbase}_${pkgver}
make -C buildQt5 DESTDIR="${pkgdir}" install
make -C buildPluginsQt5 DESTDIR="${pkgdir}" install
install -Dm 644 avidemux-qt.desktop -t "${pkgdir}/usr/share/applications"
}
# vim: ts=2 sw=2 et:
|
