blob: f276cdce3a7264ac033f341705b4662e5b9021b0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
pkgname=ark
pkgver=17.12.1
pkgrel=1.parabola1
pkgdesc='Archiving Tool, with unar support'
arch=(x86_64 i686 armv7h)
url='https://kde.org/applications/utilities/ark/'
license=(GPL)
depends=(kparts kpty libarchive libzip kitemmodels hicolor-icon-theme)
makedepends=(extra-cmake-modules kdoctools python)
optdepends=('p7zip: 7Z format support' 'unar: RAR format support')
groups=(kde-applications kdeutils)
source=("http://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig}
'libre.patch')
sha256sums=('30c133a93f9aa1e2c294addb11e38c0ed9bbff1c8ec42b468dd66b8f0987aa77'
'SKIP'
'624bd7cd221db2a80b21cd5f71c447d86091e52276f2bdb609c8916755c7d602')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7 # Albert Astals Cid <aacid@kde.org>
F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>
prepare() {
mkdir -p build
cd $pkgname-$pkgver
patch -p1 -i $srcdir/libre.patch
rm -rv plugins/clirarplugin
}
build() {
cd build
cmake ../$pkgname-$pkgver \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_LIBDIR=lib \
-DBUILD_TESTING=OFF
make
}
package() {
cd build
make DESTDIR="$pkgdir" install
}
|
