blob: cf275f60d6b32d98ea7704b132b90746f45a7297 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: schuay <jakob.gruber@gmail.com>
# Contributor: Mike Sampson <mike at sambodata dot com>
# Contributor: Adrian Stratulat <adrian.stratulat at inboxcom>
# Contributor: Anton Bazhenov <anton.bazhenov at gmail>
# Contributor: KillaB <xGenoBlast@gmail.com>
# Contributor: Callan Barrett <wizzomafizzo@gmail.com>
# Contributor: Christian Schmidt <xmucknertx@googlemail.com>
# Contributor: Sebastian Sareyko <public@nooms.de>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>
_pkgname=angband
pkgname=angband-libre
pkgver=3.5.0
pkgrel=2
pkgdesc="A roguelike dungeon exploration game based on the writings of JRR Tolkien, without nonfree artwork and sound effects"
arch=('i686' 'x86_64' 'mips64el')
url="http://rephial.org/"
license=('GPL2' 'custom')
replaces=$_pkgname
conflicts=$_pkgname
provides=$_pkgname=$pkgver
depends=('sdl_image' 'sdl_ttf' 'sdl_mixer' 'ncurses')
mksource=("http://rephial.org/downloads/${pkgver:0:3}/${_pkgname}-v${pkgver}.tar.gz" 'libre.patch')
source=("https://repo.parabolagnulinux.org/sources/${pkgname}-v${pkgver}.tar.gz")
mksource() {
cd "${srcdir}/${_pkgname}-v${pkgver}"
# remove nonfree parts from source code
patch -Np1 -i ../libre.patch
rm -v lib/xtra/sound/*.mp3
rm -v lib/xtra/graf/64x64.png
}
build() {
cd "${srcdir}/${_pkgname}-v${pkgver}"
./configure \
--prefix=/usr \
--bindir=/usr/bin \
--sysconfdir=/usr/share/angband \
--with-configpath=/usr/share/angband \
--with-libpath=/usr/share/angband \
--enable-gtk \
--enable-sdl \
--enable-sdl-mixer
make
}
package() {
cd "${srcdir}/${_pkgname}-v${pkgver}"
make DESTDIR="${pkgdir}" install
rm -f "${pkgdir}/usr/share/angband/*/delete.me"
install -Dm644 copying.txt "${pkgdir}/usr/share/licenses/${_pkgname}/COPYING"
}
mkmd5sums=('4f6ee37abdb411285deb1685ddecba6a'
'3ac39f377bea2e208308d01f4213310f')
md5sums=('82c98af3bc6e5b61787ca09e584a4e78')
|
