blob: f7d205adce19771cb19f16b350a22f7d78ef9260 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
pkgname=akonadi-contacts
pkgver=17.08.1
pkgrel=1.parabola1
pkgdesc="Libraries and daemons to implement Contact Management in Akonadi, without nonfree qt5-webengine support"
arch=(i686 x86_64 armv7h)
url="https://community.kde.org/KDE_PIM"
license=(LGPL)
depends=(akonadi grantlee kcontacts kmime prison opengl-driver)
makedepends=(extra-cmake-modules kdoctools python boost akonadi-mime kcalcore kdesignerplugin)
conflicts=(akonadi-contact)
replaces=(akonadi-contact)
source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig}
'libre.patch')
sha256sums=('89cd3a7cfe54e7b88630524413a37a04be7c1425253af82944ebbba1985cea41'
'SKIP'
'5356d5d15fd041790c2c073f6a23da9d8bcca8a65610c40fd51897de35fdcc70')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7 # Albert Astals Cid <aacid@kde.org>
F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>
prepare() {
mkdir -p build
cd $srcdir/$pkgname-$pkgver
rm -rv src/contact-editor/editor/addresseditor/webengine
patch -p1 -i ../libre.patch
}
build() {
cd build
cmake ../$pkgname-$pkgver \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DKDE_INSTALL_LIBDIR=lib \
-DBUILD_TESTING=OFF
make
}
package() {
cd build
make DESTDIR="$pkgdir" install
}
|
