blob: a1b3a657b9c64a2baebf7b33611099e19f113334 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer (Arch): Maxime Gauduin <alucryd@gmail.com>
# Contributor (Arch): mortzu <me@mortzu.de>
# Contributor (Arch): fnord0 <fnord0@riseup.net>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Contributor (Hyperbola): Márcio Silva <coadde@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
_basekernel=4.19.59_gnu-1
pkgname=acpi_call-lts
pkgver=1.1.0
pkgrel=81
_extramodules=extramodules-${_basekernel%.*}-lts
pkgrel+=.parabola1.basekernel${_basekernel%_*}
pkgdesc='A linux kernel module that enables calls to ACPI methods through /proc/acpi/call'
pkgdesc+=' (built for the linux-libre-lts kernel package)'
arch=('x86_64')
arch+=('i686' 'armv7h')
url='https://github.com/mkottman/acpi_call'
license=('GPL')
depends=(linux-libre-lts=${_basekernel%-*})
makedepends=(linux-libre-lts-headers=${_basekernel%-*} libelf)
provides=('acpi_call')
source=("acpi_call-${pkgver}.tar.gz::https://github.com/mkottman/acpi_call/archive/v${pkgver}.tar.gz")
sha256sums=('d0d14b42944282724fca76f57d598eed794ef97448f387d1c489d85ad813f2f0')
prepare() {
cd acpi_call-${pkgver}
# Fix build with Linux-libre >= 3.17-gnu
sed -i 's|acpi/acpi.h|linux/acpi.h|' acpi_call.c
# Fix build with Linux-libre >= 4.12
sed -i 's|asm/uaccess.h|linux/uaccess.h|' acpi_call.c
}
build() {
cd ${pkgname%-*}-${pkgver}
_kernver="$(cat /usr/lib/modules/${_extramodules}/version)"
make KVERSION="${_kernver}"
}
package() {
cd ${pkgname%-*}-${pkgver}
install -dm 755 "${pkgdir}"/usr/lib/{modules/${_extramodules},modules-load.d}
install -m 644 ${pkgname%-*}.ko "${pkgdir}"/usr/lib/modules/${_extramodules}/
gzip "${pkgdir}"/usr/lib/modules/${_extramodules}/${pkgname%-*}.ko
echo ${pkgname%-*} > "${pkgdir}"/usr/lib/modules-load.d/${pkgname}.conf
install -dm 755 "${pkgdir}"/usr/share/${pkgname}
cp -dr --no-preserve='ownership' {examples,support} "${pkgdir}"/usr/share/${pkgname}/
}
# vim: ts=2 sw=2 et:
|
