blob: 101fc0fc90728b98e51dc201d179036c6b87a02e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer (Arch): Maxime Gauduin <alucryd@archlinux.org>
# Contributor (Arch): mortzu <me@mortzu.de>
# Contributor (Arch): fnord0 <fnord0@riseup.net>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Contributor (Hyperbola): Márcio Silva <coadde@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
_basekernel=5.8.3
pkgname=acpi_call-dkms
pkgver=1.1.0
pkgrel=287
pkgrel+=.parabola1.basekernel${_basekernel}
pkgdesc='A linux kernel module that enables calls to ACPI methods through /proc/acpi/call - module sources'
pkgdesc+=' (for linux-libre)'
url='https://github.com/mkottman/acpi_call'
arch=('x86_64')
arch+=('i686')
license=('GPL')
depends=('dkms')
makedepends=(linux-libre-headers=${_basekernel})
provides=("acpi_call=$pkgver-${pkgrel%%.*}")
conflicts=('acpi_call')
source=("acpi_call-${pkgver}.tar.gz::https://github.com/mkottman/acpi_call/archive/v${pkgver}.tar.gz"
'0001-linux-5.6.patch'
'dkms.conf')
sha256sums=('d0d14b42944282724fca76f57d598eed794ef97448f387d1c489d85ad813f2f0'
'1f397f087fd96d5286907c90f518bbe68b0d19f83ab30bb124f76a19693a932c'
'32e6ea6523b13132c6c7838bba7fbf3d040ba2d35a892c2c356245612720df8a')
prepare() {
cd acpi_call-$pkgver
# Fix build with Linux >= 5.6
# also: Linux-libre >= 3.17-gnu (acpi.h)
# also: Linux-libre >= 4.12-gnu (uaccess.h)
patch -Np1 < ../0001-linux-5.6.patch
}
package() {
cd acpi_call-$pkgver
install -Dt "$pkgdir/usr/src/acpi_call-$pkgver" -m0644 Makefile acpi_call.c ../dkms.conf
echo acpi_call | install -Dm0644 /dev/stdin "$pkgdir/usr/lib/modules-load.d/acpi_call.conf"
mkdir -p "$pkgdir/usr/share/acpi_call"
cp -t "$pkgdir/usr/share/acpi_call" -dr --no-preserve=ownership examples support
}
|
