blob: fcf458ffd77a330d5238c6cd18a56905b56ca159 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# U-Boot: ChiliBoard
# Maintainer: André Silva <emulatorman@parabola.nu>
buildarch=4
pkgname=uboot4extlinux-chiliboard
pkgver=2014.07
pkgrel=2
pkgdesc="U-Boot with Extlinux support for ChiliBoard"
arch=('armv7h')
url="http://git.denx.de/u-boot.git/"
conflicts=('uboot-chiliboard' 'uboot4grub-chiliboard')
makedepends=('bc')
license=('GPL')
backup=(boot/extlinux/extlinux.conf)
install=${pkgname}.install
source=("ftp://ftp.denx.de/pub/u-boot/u-boot-${pkgver}.tar.bz2"
'0001-Add-linux-compiler-gcc5.h-to-fix-builds-with-gcc5.patch'
'0002-ARM-asm-io.h-use-static-inline.patch'
'0003-common-main.c-make-show_boot_progress-__weak.patch'
'0004-common-board_f-cosmetic-use-__weak-for-leds.patch'
'0005-chiliboard-support.patch'
'0006-parabola-arm-modifications.patch'
'extlinux.conf'
'uEnv.txt')
md5sums=('36d4bad687edcafa396fee607e505d4e'
'e070e8b5cf8628b6440dfc9dbd87cb65'
'318310de19110167fe15ceac3ae32f7d'
'1792346431786e1442c4059cd3f288ed'
'2a32a77f123391c02935754ced2743c2'
'5951c799b35c526f02edbcb3eb1295fc'
'35147d090738dd0c8104a565de0f404e'
'2a20e20b446f8f28cac3c7a092b0d09f'
'0afad1f6f3f8609db6e1f5bb322b2a1a')
prepare() {
cd u-boot-${pkgver}
patch -Np1 -i ../0001-Add-linux-compiler-gcc5.h-to-fix-builds-with-gcc5.patch
patch -Np1 -i ../0002-ARM-asm-io.h-use-static-inline.patch
patch -Np1 -i ../0003-common-main.c-make-show_boot_progress-__weak.patch
patch -Np1 -i ../0004-common-board_f-cosmetic-use-__weak-for-leds.patch
patch -Np1 -i ../0005-chiliboard-support.patch
patch -Np1 -i ../0006-parabola-arm-modifications.patch
}
build() {
cd u-boot-${pkgver}
unset CFLAGS CXXFLAGS LDFLAGS
make distclean
make chiliboard_config
make
}
package() {
cd u-boot-${pkgver}
mkdir -p "${pkgdir}"/boot/extlinux
cp MLO u-boot.img "${srcdir}"/uEnv.txt "${pkgdir}"/boot
cp "${srcdir}"/extlinux.conf "${pkgdir}"/boot/extlinux
}
|
