blob: a01dae3982a13fe6d1eafac9a58e669b68eff384 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Stéphane Gaudreault <stephane@archlinux.org>
# Contributor: Sergej Pupykin <pupykin.s@arch@gmail.com>
# Contributor: Andreas Wagner <Andreas.Wagner@em.uni-frankfurt.de>
pkgname=s-nail
pkgver=14.9.11
pkgrel=1
pkgdesc='Mail processing system with a command syntax reminiscent of ed'
url='http://www.sdaoden.eu/code.html#s-nail'
license=('custom:BSD')
arch=('x86_64' 'ppc64le')
depends=('openssl' 'krb5' 'libidn2')
optdepends=('smtp-forwarder: for sending mail')
validpgpkeys=('EE19E1C1F2F7054F8D3954D8308964B51883A0DD')
source=("https://www.sdaoden.eu/downloads/${pkgname}-${pkgver}.tar.xz"{,.asc})
sha256sums=('258d818449da889c5fc4976215698a817c0a3818fb77dd565fa9fe6afed0023e'
'SKIP')
groups=('base')
backup=('etc/mail.rc')
replaces=('mailx' 'mailx-heirloom' 'heirloom-mailx')
provides=('mailx' 'mailx-heirloom' 'heirloom-mailx')
conflicts=('mailx' 'mailx-heirloom' 'heirloom-mailx')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
CFLAGS+=" $CPPFLAGS"
make \
VAL_PREFIX=/usr \
VAL_SYSCONFDIR=/etc \
VAL_LIBEXECDIR=/usr/lib \
VAL_MAIL=/var/spool/mail \
VAL_SID= VAL_MAILX=mail \
OPT_AUTOCC=0 \
config
make MAKEJOBS=--jobs build
}
check() {
cd "${srcdir}/${pkgname}-${pkgver}"
make test < /dev/null
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
ln -sf mail "${pkgdir}"/usr/bin/mailx
ln -sf mail.1.gz "${pkgdir}"/usr/share/man/man1/mailx.1.gz
install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}
|
