# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>

pkgname=("md" "emacs-mdmua")
pkgver=0.81
pkgrel=4
arch=('any')
url="https://github.com/nicferrier/$_pkgname"
license=('GPL3')

makedepends=(python-distribute)

#__gitbranch=1d69744 # This is the commit that is 0.81
__gitbranch=455b6b4 # this is currently HEAD (has bugfixes)
source=("nicferrier-md-${__gitbranch}.tar.gz::https://github.com/nicferrier/$pkgname/tarball/${__gitbranch}")

build() {
  cd "${srcdir}/nicferrier-md-${__gitbranch}"

  # fix typo
  sed -i 's/pyprofyfs/pyproxyfs/' setup.py
}

package_md() {
  pkgdesc="A maildir client and library."
  depends=('python' 'python-pyproxyfs')

  cd "${srcdir}/nicferrier-md-${__gitbranch}"
  python setup.py install --root="$pkgdir/" --optimize=1
}

package_emacs-mdmua() {
  pkgdesc="An Emacs mail user agent (MUA) build around md."
  pkgver='0.72'
  depends=("md=0.81" 'emacs>=24')

  cd "${srcdir}/nicferrier-md-${__gitbranch}"
  cd useragents/emacs
  install -d ${pkgdir}/usr/share/emacs/site-lisp
  install -m 644 *.el ${pkgdir}/usr/share/emacs/site-lisp
}

md5sums=('452727348df2f51d7eddade709aceb1c')