# Maintainer: Henry Jensen <hjensen@connochaetos.org>
# Contributor: Luke Shumaker <lukeshu@sbcglobal.net>

_pkgname=iceweasel
_pkgver=9.0
_debver=9.0.1
_debrel='1~bpo60+1' # bpo=backport (from sid to sqeeze)
_repo_url=http://mozilla.debian.net/pool/iceweasel-release/i/iceweasel

pkgname=$_pkgname-libre-current
pkgver=${_debver}.${_debrel}
pkgrel=1

pkgdesc="Libre version of Iceweasel, based on the Firefox browser."
arch=('i586' 'i686' 'x86_64')
url="http://www.geticeweasel.org/"
license=('GPL2' 'MPL' 'LGPL')
depends=('desktop-file-utils')
makedepends=('zip' 'pkg-config' 'diffutils' 'python' 'wireless_tools' 'yasm' 'mesa' 'quilt')
provides=("${_pkgname}")
conflicts=('firefox' 'icecat' "${_pkgname}")
replaces=('firefox' 'icecat')
install=iceweasel.install
source=("${_repo_url}/iceweasel_${_debver}.orig.tar.bz2"
        "${_repo_url}/iceweasel_${_debver}-${_debrel}.debian.tar.gz"
        # Misc
        mozconfig
        mozilla-firefox-1.0-lang.patch
        xulrunner-copy-stub.patch
        libre.patch
        # Search engines
        arch-linux-wiki.xml
        internet-archive.xml
        jamendo-en.xml
        logless-search.xml
        scroogle-ssl-english.xml
        yacy.xml
        duck-duck-go-ssl.xml
        duck-duck-go-lite.xml
        # Default options
        firefox.js
        region.properties)

build() {
  msg2 "Applying Debian patches..."
  cd "${srcdir}"
  # This will simulate dpkg-source -x iceweasel_${_debver}-${_debrel}.dsc
  export QUILT_PATCHES=debian/patches
  export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
  export QUILT_DIFF_ARGS='--no-timestamps'
  mv mozilla-release "${_pkgname}-${_debver}"
  mv debian "${_pkgname}-${_debver}"
  cd "${_pkgname}-${_debver}"
  quilt push -a
  find .pc -name .timestamp -delete # why isn't --no-timestamps doing this?

  # This will make life more sane
  cd "${srcdir}"
  ln -s "${_pkgname}-${_debver}" "${_pkgname}-${pkgver}"

  msg2 "Applying Parabola/ConnochaetOS patches..."
  cd "${srcdir}/${_pkgname}-${pkgver}/"
  patch -Np1 -i "${srcdir}/mozilla-firefox-1.0-lang.patch"
  patch -p1 < ../libre.patch
#  patch -Np0 -i "${srcdir}/xulrunner-copy-stub.patch"
  
  cp --remove-destination ${srcdir}/region.properties ./browser/locales/en-US/chrome/browser-region/

  msg2 "Starting build..."
  cp "${srcdir}/mozconfig" .mozconfig

  #make -j1 -f client.mk build MOZ_MAKE_FLAGS="${MAKEFLAGS}"
  ./configure

#  touch config*

  make MOZ_MAKE_FLAGS="${MAKEFLAGS}"
  msg2 "Build complete"
}

package() {

  cd "${srcdir}/${_pkgname}-${pkgver}/"
  #make -j1 -f client.mk DESTDIR="${pkgdir}" install
  make install DESTDIR="${pkgdir}"

  msg2 "Finishing..."

  install -m755 -d ${pkgdir}/usr/share/applications
  install -m755 -d ${pkgdir}/usr/share/pixmaps
  install -m755 -d ${pkgdir}/usr/share/icons/hicolor/16x16/apps
  install -m755 -d ${pkgdir}/usr/share/icons/hicolor/32x32/apps
  install -m755 -d ${pkgdir}/usr/share/icons/hicolor/64x64/apps
  install -m755 -d ${pkgdir}/usr/share/icons/hicolor/scalable/apps

  install -m644 ${srcdir}/${_pkgname}-${pkgver}/debian/iceweasel.desktop ${pkgdir}/usr/share/applications/ || return 1
  install -m644 ${srcdir}/${_pkgname}-${pkgver}/debian/branding/default16.png ${pkgdir}/usr/share/icons/hicolor/16x16/apps/iceweasel.png
  install -m644 ${srcdir}/${_pkgname}-${pkgver}/debian/branding/default32.png ${pkgdir}/usr/share/icons/hicolor/32x32/apps/iceweasel.png
  install -m644 ${srcdir}/${_pkgname}-${pkgver}/debian/branding/default64.png ${pkgdir}/usr/share/icons/hicolor/64x64/apps/iceweasel.png
  install -m644 ${srcdir}/${_pkgname}-${pkgver}/debian/branding/iceweasel_icon.svg ${pkgdir}/usr/share/icons/hicolor/scalable/apps/iceweasel.svg
  

  msg2 "Removing proprietary and anti-privacy search engines"
  rm -f ${pkgdir}/usr/lib/${_pkgname}-${_pkgver}/searchplugins/{google,answers,amazondotcom,eBay,yahoo,bing}.xml
  msg2 "And provide better ones..."
  install -m755 -d ${pkgdir}/usr/lib/${_pkgname}-${_pkgver}/searchplugins/
  install -m644 ${srcdir}/*.xml ${pkgdir}/usr/lib/${_pkgname}-${_pkgver}/searchplugins/
  rm -rvf ${pkgdir}/usr/lib/iceweasel-devel-${_pkgver}
  rm -rvf ${pkgdir}/usr/include

}
md5sums=('bd656a24d0ba3d4ca7b68aca8081a07d'
         '8846b9cce4ce7a82ec9995510efce867'
         '5e2574eef71ee1437e2f8e7481c67893'
         'bd5db57c23c72a02a489592644f18995'
         '5a1938673a367b20ecfa009a5eb767aa'
         '9609e77182cc300e3fe9d4b0c7e7efb4'
         '3403175087e584a8c5e840cc62310cd9'
         '462c68585461f8cdc23c93c46f6ee4cf'
         '2d492295c4308f9bba9ece28d8b3af2d'
         '937ac0e5392b060d93bd33e761fbfa51'
         'cf97082e77e3ef5f1bd74b1db9329965'
         '24528ca3f7f1e1a0ba735231aa3ac1de'
         'c5f00b6b24222aacd5a749d1f59c4d24'
         'e1bda0854de7d764f7401c81bb82b5ef'
         '9952048383966926eea6d67384102425'
         'f1c76e7e244257856a386ca2de69bdf0')