#Contributor: Danie Roux <accounts@danieroux.com>
#Maintainer: Buce <dmbuce@gmail.com>

# This requires lukeshu's modified makepkg to build

pkgname=etckeeper
pkgver=0.63
pkgrel=2.1
pkgdesc="collection of tools to let /etc be stored in a git, hg, bzr or darcs repository."
arch=('any')
backup=('etc/etckeeper/etckeeper.conf')
url="http://kitenet.net/~joey/code/etckeeper/"
license=('GPL2')
provides=('etckeeper')
depends=('inetutils' 'python2')
makedepends=('bzr') # bzr must be there at compile time to have bzr support
optdepends=('git' 'hg' 'bzr' 'darcs')
source=("etckeeper-$pkgver.tar::git://git.kitenet.net/etckeeper#${pkgver}"
        etckeeper-archlinux.conf)

build() {
  cd "$srcdir/etckeeper-$pkgver"

  # use python2
  sed -i 's@^#!/usr/bin/python$@&2@' etckeeper-bzr/__init__.py

  make CONFFILE="$srcdir/etckeeper-archlinux.conf" build
}

package() {
  cd "$srcdir/etckeeper-$pkgver"

  make CONFFILE="$srcdir/etckeeper-archlinux.conf" DESTDIR=$pkgdir install
}

md5sums=('0373375e93cb7122bb0ae4749e63c0d9'
         '99d8d2838f49fa0f2f21c9e37948100d')