# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=linux-libre-dtb
_pkgbasever=4.1-gnu
_pkgver=4.1.6-gnu

_srcname=linux-${_pkgbasever%-*}
pkgver=${_pkgver//-/_}
pkgrel=1
rcnrel=armv7-x2
pkgdesc='dtb files for Linux-libre'
arch=('armv7h')
url=('http://linux-libre.fsfla.org/')
license=('GPL2')
makedepends=('git')
source=("http://linux-libre.fsfla.org/pub/linux-libre/releases/${_pkgbasever}/linux-libre-${_pkgbasever}.tar.xz"
        "http://linux-libre.fsfla.org/pub/linux-libre/releases/${_pkgbasever}/linux-libre-${_pkgbasever}.tar.xz.sign"
        "http://linux-libre.fsfla.org/pub/linux-libre/releases/${_pkgver}/patch-${_pkgbasever}-${_pkgver}.xz"
        "http://linux-libre.fsfla.org/pub/linux-libre/releases/${_pkgver}/patch-${_pkgbasever}-${_pkgver}.xz.sign"
        # the main kernel config files
        'config.armv7h'
        "https://repo.parabola.nu/other/rcn-libre/patches/${_pkgver%-*}/rcn-libre-${_pkgver%-*}-${rcnrel}.patch"
        "https://repo.parabola.nu/other/rcn-libre/patches/${_pkgver%-*}/rcn-libre-${_pkgver%-*}-${rcnrel}.patch.sig"
        '0001-ARM-atags-add-support-for-Marvell-s-u-boot.patch'
        '0002-ARM-atags-fdt-retrieve-MAC-addresses-from-Marvell-bo.patch'
        '0003-SMILE-Plug-device-tree-file.patch'
        '0004-fix-mvsdio-eMMC-timing.patch'
        '0005-net-smsc95xx-Allow-mac-address-to-be-set-as-a-parame.patch'
        '0006-ARM-TLV320AIC23-SoC-Audio-Codec-Fix-errors-reported-.patch'
        '0007-set-default-cubietruck-led-triggers.patch'
        '0008-USB-armory-support.patch')
sha256sums=('48b2e5ea077d0a0bdcb205e67178e8eb5b2867db3b2364b701dbc801d9755324'
            'SKIP'
            '335d3e07319ddf393c69e047c27bc5d28ee9e6126282619e3364db56a4331d34'
            'SKIP'
            'bddc6542d1a68330e867efca6657cc57e9eeb8f83ec86e5580dc1b6c89332f13'
            'b06ab02787e6a61227d91faeaa3f230a3807f6426c388129a1d89150374e8b5b'
            'SKIP'
            '203b07cc241f2374d1e18583fc9940cc69da134f992bff65a8b376c717aa7ea7'
            '28fb8c937c2a0dc824ea755efba26ac5a4555f9a97d79f4e31f24b23c5eae59c'
            '39bfd7f6e2df0b87b52488462edb2fbcfaf9e3eb2a974fc7b3bc22147352fece'
            '59444ed7dce62697f1c35be340b740899e1d71398b334c419ad07cea838c6ed6'
            '90cff98e43322e79c8d8b1c6456a328650f6af3ebf018086a82ab690a688da5d'
            'ed6cf79434d3b1c10e0e141ab6bdc2aa9abfe7e7df6bbb24b2097c0e0d62ac17'
            '2c3df3d9a3d8fe11fefc485167a81c6fc53635b04ba0312bef144505dc0a6ce4'
            '0f6b0146096ee7a04938d39a013c23cfd8719f3bef0956b5c88a33e7d7ecafdc')
validpgpkeys=(
              '474402C8C582DAFBE389C427BCB7CF877E7D47A7' # Alexandre Oliva
              'C92BAA713B8D53D3CAE63FC9E6974752F9704456' # André Silva
)

prepare() {
  cd "${srcdir}/${_srcname}"

  # add upstream patch
  if [ "${_pkgbasever}" != "${_pkgver}" ]; then
    patch -p1 -i "${srcdir}/patch-${_pkgbasever}-${_pkgver}"
  fi

  # RCN patch (CM3 firmware deblobbed)
  git apply -v "${srcdir}/rcn-libre-${_pkgver%-*}-${rcnrel}.patch"

  # ALARM patches
  patch -p1 -i "${srcdir}/0001-ARM-atags-add-support-for-Marvell-s-u-boot.patch"
  patch -p1 -i "${srcdir}/0002-ARM-atags-fdt-retrieve-MAC-addresses-from-Marvell-bo.patch"
  patch -p1 -i "${srcdir}/0003-SMILE-Plug-device-tree-file.patch"
  patch -p1 -i "${srcdir}/0004-fix-mvsdio-eMMC-timing.patch"
  patch -p1 -i "${srcdir}/0005-net-smsc95xx-Allow-mac-address-to-be-set-as-a-parame.patch"
  patch -p1 -i "${srcdir}/0006-ARM-TLV320AIC23-SoC-Audio-Codec-Fix-errors-reported-.patch"
  patch -p1 -i "${srcdir}/0007-set-default-cubietruck-led-triggers.patch"
  patch -p1 -i "${srcdir}/0008-USB-armory-support.patch"

  cat "${srcdir}/config.${CARCH}" > ./.config

  # load configuration
  # Configure the kernel. Replace the line below with one of your choice.
  #make menuconfig # CLI menu for configuration
  #make nconfig # new CLI menu for configuration
  #make xconfig # X-based configuration
  #make oldconfig # using old config from previous kernel version
  # ... or manually edit .config

  # rewrite configuration
  yes "" | make config >/dev/null
}

build() {
  cd "${srcdir}/${_srcname}"

  make ${MAKEFLAGS} dtbs
}

package() {
  cd "${srcdir}/${_srcname}"

  mkdir -p "${pkgdir}"/boot/dtbs
  cp arch/arm/boot/dts/*.dtb "${pkgdir}/boot/dtbs"
}