# Maintainer: Márcio Silva <coadde@parabola.nu>

pkgbase=waf
pkgname=('python-waf' 'python2-waf')
pkgver=1.8.20
pkgrel=1
pkgdesc='The meta build system'
arch=('any')
url="https://$pkgbase.io"
license=('BSD3')
makedepends=('python' 'python2')
source=("$url/$pkgbase-$pkgver.tar.bz2"{,.asc})
md5sums=('1e188c5179f47964050b08863e9026a0'
         'SKIP')
validpgpkeys=('E6EEAF4A06B3C4CDAC71D4DE67A565EDFDF90E64')

build() {
  rm -v $pkgbase-$pkgver/waf
  mv -v {,python-}$pkgbase-$pkgver
  cp -va python{,2}-$pkgbase-$pkgver

  cd $srcdir/python-$pkgbase-$pkgver
  ./configure

  cd $srcdir/python2-$pkgbase-$pkgver
  sed -i 's|/usr/bin/env python|/usr/bin/env python2|
         ' waf-light
  ./configure
}

package_python-waf() {
  pkgdesc='The meta build system (Python 3)'
  depends=('python')

  cd $srcdir/python-$pkgbase-$pkgver
  mkdir -pvm 755 $pkgdir/usr/bin
  cp -va waf $pkgdir/usr/bin/waf
}

package_python2-waf() {
  pkgdesc='The meta build system (Python 2)'
  depends=('python2')

  cd $srcdir/python2-$pkgbase-$pkgver
  mkdir -pvm 755 $pkgdir/usr/bin
  cp -va waf $pkgdir/usr/bin/waf2
}