pkgname=tinc-pre
pkgver=1.1pre11
pkgrel=1
pkgdesc="VPN (Virtual Private Network) daemon (Pre-release)"
arch=(i686 x86_64)
url="http://www.tinc-vpn.org/"
license=('GPL')
depends=('lzo2' 'zlib' 'openssl')
optdepends=('wxpython: gui support')
provides=('tinc-pre')
conflicts=('tinc')
source=(http://www.tinc-vpn.org/packages/tinc-$pkgver.tar.gz{,.sig}
        tincd@.service)
sha256sums=('942594563d3aef926a2d04e9ece90c16daf1c700e99e3b91ff749e8377fbf757'
            'SKIP'
            '43d086b76e2a6ff6d91a2ace2d6d048fc7109fefecd5047ab6c437ba0e9252ed')

build() {
  cd "$srcdir/tinc-$pkgver"
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --sbindir=/usr/bin
  make
}

package() {
  cd "$srcdir/tinc-$pkgver"

  make DESTDIR="$pkgdir" install

  install -dm755 "$pkgdir"/usr/share/tinc/examples
  tar xozvf doc/sample-config.tar.gz -C $pkgdir/usr/share/tinc/examples
  find "$pkgdir"/usr/share/tinc/examples -type f -exec chmod 644 {} +
  find "$pkgdir"/usr/share/tinc/examples -type d -exec chmod 755 {} +

  install -Dm644 "$srcdir/tincd@.service" \
                 "$pkgdir/usr/lib/systemd/system/tincd@.service"

  sed -e 's,#!/usr/bin/python,#!/usr/bin/python2,' \
      -i $pkgdir/usr/bin/tinc-gui
}