# Maintainer (Arch): Anatol Pomozov
# Contributor: Andreas Grapentin <andreas@grapentin.org>

# parabola changes and rationale:
#  - adapted from aarch64-linux-gnu-glibc

_target=riscv64-linux-gnu
pkgname=$_target-glibc
pkgver=2.27
pkgrel=1
_commit=be176490b818b65b5162c332eb6b581690b16e5c
pkgdesc="GNU C Library riscv64 target"
arch=('x86_64')
url='http://www.gnu.org/software/libc/'
license=('GPL' 'LGPL')
depends=($_target-gcc $_target-linux-api-headers)
options=(!buildflags !strip staticlibs)
source=(http://ftp.gnu.org/gnu/libc/glibc-$pkgver.tar.xz{,.sig})
sha1sums=('1f7a9c43026484943ef7cf6885f2176a2bc1e093'
          'SKIP')
validpgpkeys=(7273542B39962DF7B299931416792B4EA25340F8)  # "Carlos O'Donell <carlos@systemhalted.org>"

prepare() {
  mkdir -p glibc-build
}

build() {
  cd glibc-build

  echo "slibdir=/lib" >> configparms
  echo "rtlddir=/lib" >> configparms
  echo "sbindir=/bin" >> configparms
  echo "rootsbindir=/bin" >> configparms

  unset LD_LIBRARY_PATH

  export BUILD_CC=gcc
  export CC=${_target}-gcc
  export CXX=${_target}-g++
  export AR=${_target}-ar
  export RANLIB=${_target}-ranlib

  ../glibc-$pkgver/configure \
      --prefix=/usr \
      --target=$_target \
      --host=$_target \
      --build=$CHOST \
      --libdir=/usr/lib \
      --libexecdir=/usr/lib \
      --with-headers=/usr/$_target/include \
      --with-bugurl=https://bugs.archlinux.org/ \
      --enable-add-ons \
      --enable-obsolete-rpc \
      --enable-kernel=3.0.0 \
      --enable-bind-now \
      --disable-profile \
      --enable-shared \
      --disable-multilib \
      --disable-werror

  make
}

package() {
  cd glibc-build

  make install_root=$pkgdir/usr/$_target install
}