# $Id$
# Maintainer (Arch): Anatol Pomozov <anatol.pomozov@gmail.com>
# Contributor: Andreas Grapentin <andreas@grapentin.org>

# parabola changes and rationale:
#  - adapted from aarch64-linux-gnu-gdb

_target=riscv64-linux-gnu
pkgname=$_target-gdb
_gitname=riscv-binutils-gdb
pkgver=8.0.50_20180227
pkgrel=1
pkgdesc='The GNU Debugger for the riscv64 target'
arch=(x86_64)
url='https://github.com/riscv/riscv-binutils-gdb'
license=(GPL3)
depends=(xz ncurses expat python guile2.0 gdb-common mpfr)
makedepends=(git)
options=(!emptydirs)
source=("git+https://github.com/riscv/riscv-binutils-gdb#branch=riscv-next")
sha256sums=('SKIP')

pkgver() {
  cd "${srcdir}/${_gitname}"

  cat gdb/version.in | sed "s/\.DATE-git/_$(date +%Y%m%d)/"
}

prepare() {
  cd "${srcdir}/${_gitname}"

  sed -i "/ac_cpp=/s/\$CPPFLAGS/\$CPPFLAGS -O2/" libiberty/configure
}

build() {
  cd "${srcdir}/${_gitname}"

  ./configure \
    --target=$_target \
    --with-arch=rv64gc \
    --with-abi=lp64d \
    --prefix=/usr \
    --enable-languages=c,c++ \
    --disable-multilib \
    --with-system-readline \
    --disable-nls \
    --with-python=/usr/bin/python3 \
    --with-guile=guile-2.0 \
    --with-system-gdbinit=/etc/gdb/gdbinit

  make all-gdb
}

package() {
  cd "${srcdir}/${_gitname}"

  make DESTDIR="$pkgdir" install-gdb

  # Following files conflict with 'gdb' package
  rm -r "$pkgdir"/usr/share/info
  rm -r "$pkgdir"/usr/share/gdb
  rm -r "$pkgdir"/usr/include/gdb
  rm -r "$pkgdir"/usr/share/man/man5
}