# $Id$
# Maintainer (Arch): speps <speps at aur dot archlinux dot org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>

# parabola changes and rationale:
#  - adapted from qupzilla, but downgraded to last WebKit compatible version
#  - integrated (partially) patchset from debian jessie

pkgname=qupzilla1
pkgver=1.8.9
pkgrel=1
_debver=dfsg1-3.1
pkgdesc="Cross-platform QtWebKit browser"
arch=(x86_64 i686 armv7h)
url="https://www.qupzilla.com/"
license=(GPL3)
depends=(qt5-webkit qt5-x11extras qt5-svg openssl-1.0)
makedepends=(qt5-tools kwallet libgnome-keyring quilt)
optdepends=('kwallet: kf5 kwallet integration' 'libgnome-keyring: gnome keyring integration')
conflicts=(${pkgname%1})
source=(https://github.com/QupZilla/qupzilla/releases/download/v$pkgver/QupZilla-$pkgver.tar.xz
        http://http.debian.net/debian/pool/main/q/qupzilla/qupzilla_$pkgver~$_debver.debian.tar.xz)
sha256sums=('620ffb10a3f6b3f596c2c38a84d9c320cb66dd2d5e6701e8e31945e26308fcac'
            '5b0dd1d550422ae0effae722251a590cb177f996ebd281027638ab72c8d73da6')

prepare() {
  cd QupZilla-$pkgver

  # disable debian hardening patch (doing it ourselves)
  sed -i '/hardening\.patch/d' "$srcdir"/debian/patches/series

  export QUILT_PATCHES="$srcdir"/debian/patches
  export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
  export QUILT_DIFF_ARGS='--no-timestamps'
  quilt push -av

  # build against openssl-1.0 and fortify source
  cat >> src/defines.pri << EOF
QMAKE_CPPFLAGS *= -I/usr/include/openssl-1.0 $CPPFLAGS
QMAKE_CFLAGS   *= -I/usr/include/openssl-1.0 $CFLAGS
QMAKE_CXXFLAGS *= -I/usr/include/openssl-1.0 $CXXFLAGS
QMAKE_LFLAGS   *= $LDFLAGS
EOF
  # link against libcrypto.so.1.0.0 as well
  sed -i 's#-lcrypto#-l:libcrypto.so.1.0.0#' src/lib/lib.pro

  # fix ui generation issue
  # https://bugreports.qt.io/browse/QTBUG-65251
  sed -i 's# notr="true"##' src/lib/webtab/searchtoolbar.ui
}

build() {
  cd QupZilla-$pkgver
  export USE_WEBGL=true \
    QUPZILLA_PREFIX=/usr/ \
    KDE_INTEGRATION=true \
    GNOME_INTEGRATION=true
  qmake

  make
}

package() {
  cd QupZilla-$pkgver
  make INSTALL_ROOT="$pkgdir/" install

  # zsh completion
  install -Dm644 linux/completion/_${pkgname%1} \
    "$pkgdir/usr/share/zsh/site-functions/_${pkgname%1}"
}