pkgname="papis"
pkgver=0.7
pkgrel=1
pkgdesc="Powerful and highly extensible command-line based document and bibliography manager."
arch=(any)
url="https://github.com/papis/papis"
license=('GPLv3')
depends=("python-setuptools"
         "python-papis_python_rofi"
         "python-requests"
         "python-argcomplete"
         "python-pyparsing"
         "arxiv2bib"
         "python-yaml"
         "python-chardet"
         "python-beautifulsoup4"
         "python-vobject"
         "python-prompt_toolkit"
         "python-bibtexparser"
         "python-unidecode"
         "python-pyparser"
         "python-pypi-magic"
         "python-pylibgen"
         "python-urwid"
         "python-habanero"
         "python-slugify"
         "python-click")
source=($pkgname-$pkgver.tar.gz::https://github.com/papis/papis/archive/v$pkgver.tar.gz
        $pkgname-vim-gui-add-notes-edit-key.patch
        $pkgname-click-0.7.patch::https://github.com/papis/papis/commit/7414634a11c61268a98edd26a4de2d65cb44a28b.patch)
sha256sums=('77381dfe764aaf1d0add1ed943697085a6c2cd596448681764678ae95490901c'
            'ec7a2ada63b5eac58cc89e0230ef6db3438357c2669b7c0f88e247e0266cbe53'
            '389bb2a6b309f949f1be6ac400f4ea7f80eac2f5a7101d98a0f1e0b8ce2a04d1')

prepare() {
	cd "$srcdir/$pkgname-$pkgver"
  patch -Np1 -i "$srcdir/$pkgname-vim-gui-add-notes-edit-key.patch"
  patch -Np1 -i "$srcdir/$pkgname-click-0.7.patch"
}

build () {
	cd "$srcdir/$pkgname-$pkgver"
  sed -i "s/.*configparser/#&/" setup.py
	python setup.py build
}

package() {
	cd "$srcdir/$pkgname-$pkgver"
	python setup.py install --root="$pkgdir/" --prefix="/usr"
}