# Maintainer (Manjaro): artoo <artoo@manjaro.org>
# Contributor (Manjaro): williamh <williamh@gentoo.org>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=opentmpfiles
pkgver=0.1.3
pkgrel=2
pkgdesc="A standalone utility for handling systemd-style tmpfiles.d settings"
arch=('any')
url="https://github.com/OpenRC/opentmpfiles/archive"
license=('BSD2')
groups=('openrc-base')
depends=('openrc')
backup=('etc/conf.d/opentmpfiles-dev'
        'etc/conf.d/opentmpfiles-setup')
source=("${pkgname}-${pkgver}.tar.gz::${url}/${pkgver}.tar.gz")
sha256sums=('1fdd4587c62d815296fb4162002cf001e3ed7aae8727d9b4360f527169e6b3be')

_inst_initd(){
    install -Dm755 openrc/$1.initd ${pkgdir}/etc/init.d/$1
}

_inst_confd(){
    install -Dm755 openrc/$1.confd ${pkgdir}/etc/conf.d/$1
}

package() {
    cd "${srcdir}/${pkgname}-${pkgver}"
    make bindir="/usr/bin" DESTDIR="${pkgdir}" install

    for f in opentmpfiles-dev opentmpfiles-setup; do
        _inst_confd "$f"
        _inst_initd "$f"
    done

    install -dm755 ${pkgdir}/etc/runlevels/{boot,sysinit}
    ln -snf "/etc/init.d/opentmpfiles-dev" "${pkgdir}/etc/runlevels/sysinit/opentmpfiles-dev"
    ln -snf "/etc/init.d/opentmpfiles-setup" "${pkgdir}/etc/runlevels/boot/opentmpfiles-setup"

    ln -snf "/usr/bin/tmpfiles" "${pkgdir}/usr/bin/systemd-tmpfiles"

    install -dm755 "${pkgdir}/usr/share/licenses/${pkgname}"
    install -m644 "${srcdir}/${pkgname}-${pkgver}/license" "${pkgdir}/usr/share/licenses/${pkgname}/"
}