# Maintainer (AUR): Jakob Gahde <j5lx@fmail.co.uk>
# Contributor (AUR): Serge Zirukin <ftrvxmtrx@gmail.com>
# Contributor (AUR): Sergei Lebedev <superbobry@gmail.com
# Contributor (AUR): serp <serp256 at gmail dot com>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

# parabola changes and rationale:
#  - renamed tarball to avoid collisions
#  - updated package to 2.7.1
#  - added missing makedepends: cppo

_pkgname=lwt
pkgname=ocaml-${_pkgname}
pkgver=2.7.1
pkgrel=1
pkgdesc="A library for cooperative threads in OCaml"
arch=('i686' 'x86_64' 'armv7h')
url="http://ocsigen.org/${_pkgname}/"
license=('custom:LGPL with OpenSSL linking exception')
depends=('ocaml' 'camlp4' 'ocaml-ppx_tools' 'ocaml-react' 'ocaml-result' 'ocaml-ssl' 'libev' 'glib2')
makedepends=('ocamlbuild' 'ocaml-findlib' 'cppo')
source=("$pkgname-$pkgver.tar.gz::https://github.com/ocsigen/${_pkgname}/archive/${pkgver}.tar.gz")
sha256sums=('43c0541c185f9db4ef7e44703bd75b832dc7a69ccc9905dd413d08563d44d639')
options=('!strip' '!makeflags' 'staticlibs')

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"

  echo '<src/top/*.*>: use_compiler_libs' >> _tags
  # What requires what?
  # --enable-glib      glib2
  # --enable-react     ocaml-react
  # --enable-ssl       ocaml-ssl
  ocaml setup.ml -configure --enable-react \
                            --enable-glib \
                            --enable-ssl \
                            --enable-camlp4 \
                            --enable-ppx \
                            --disable-debug \
                            --prefix "${pkgdir}/usr"
  make
}


package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"

  export OCAMLFIND_DESTDIR="${pkgdir}$(ocamlfind printconf destdir)"
  install -dm755 "${OCAMLFIND_DESTDIR}/stublibs"
  make install
  install -Dm 644 "doc/COPYING" "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}