# $Id$
# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>
# Maintainer (AUR): Tom Richards <tom@tomrichards.net>
# Maintainer (Arch): Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Maintainer (Arch): Sébastien Luttringer
# Contributor (Arch): Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor (Arch): Miroslaw Szot <mss@czlug.icis.pcz.pl>
# Contributor (Arch): Daniel Micay <danielmicay@gmail.com>

pkgname=nginx-passenger
_nginxver=1.6.3
_passengerver=5.0.4
pkgver=$_nginxver.passenger.$_passengerver
pkgrel=1
pkgdesc='Lightweight HTTP server and IMAP/POP3 proxy server'
pkgdesc+=" (with Passenger module)"
conflicts=('nginx')
provides=("nginx=$_nginxver")
arch=('i686' 'x86_64')
url='http://nginx.org'
license=('custom')
depends=('pcre' 'zlib' 'openssl')
depends+=("passenger=$_passengerver")
depends+=('ruby' 'ruby-rack' 'curl')
makedepends=('hardening-wrapper')
backup=('etc/nginx/fastcgi.conf'
        'etc/nginx/fastcgi_params'
        'etc/nginx/koi-win'
        'etc/nginx/koi-utf'
        'etc/nginx/mime.types'
        'etc/nginx/nginx.conf'
        'etc/nginx/scgi_params'
        'etc/nginx/uwsgi_params'
        'etc/nginx/win-utf'
        'etc/logrotate.d/nginx')
install=nginx.install
source=($url/download/nginx-$_nginxver.tar.gz
        passenger-$_passengerver.tar.gz::https://github.com/phusion/passenger/archive/release-$_passengerver.tar.gz
        service
        logrotate)

build() {
  cd "$srcdir/passenger-release-$_passengerver"
  _nginx_addon_dir=$(bin/passenger-config --nginx-addon-dir)

  cd "$srcdir/nginx-$_nginxver"
  ./configure \
    --prefix=/etc/nginx \
    --conf-path=/etc/nginx/nginx.conf \
    --sbin-path=/usr/bin/nginx \
    --pid-path=/run/nginx.pid \
    --lock-path=/run/lock/nginx.lock \
    --user=http \
    --group=http \
    --http-log-path=/var/log/nginx/access.log \
    --error-log-path=stderr \
    --http-client-body-temp-path=/var/lib/nginx/client-body \
    --http-proxy-temp-path=/var/lib/nginx/proxy \
    --http-fastcgi-temp-path=/var/lib/nginx/fastcgi \
    --http-scgi-temp-path=/var/lib/nginx/scgi \
    --http-uwsgi-temp-path=/var/lib/nginx/uwsgi \
    --with-imap \
    --with-imap_ssl_module \
    --with-ipv6 \
    --with-pcre-jit \
    --with-file-aio \
    --with-http_dav_module \
    --with-http_gunzip_module \
    --with-http_gzip_static_module \
    --with-http_realip_module \
    --with-http_spdy_module \
    --with-http_ssl_module \
    --with-http_stub_status_module \
    --with-http_addition_module \
    --with-http_degradation_module \
    --with-http_flv_module \
    --with-http_mp4_module \
    --with-http_secure_link_module \
    --with-http_sub_module \
    --add-module="$_nginx_addon_dir"

  make
}

package() {
  cd "$srcdir/nginx-$_nginxver"
  make DESTDIR="$pkgdir" install

  install -Dm644 contrib/vim/ftdetect/nginx.vim \
    "$pkgdir"/usr/share/vim/vimfiles/ftdetect/nginx.vim
  install -Dm644 contrib/vim/syntax/nginx.vim \
    "$pkgdir"/usr/share/vim/vimfiles/syntax/nginx.vim
  install -Dm644 contrib/vim/indent/nginx.vim \
    "$pkgdir"/usr/share/vim/vimfiles/indent/nginx.vim

  sed -e 's|\<user\s\+\w\+;|user html;|g' \
    -e '44s|html|/usr/share/nginx/html|' \
    -e '54s|html|/usr/share/nginx/html|' \
    -i "$pkgdir"/etc/nginx/nginx.conf

  rm "$pkgdir"/etc/nginx/*.default

  install -d "$pkgdir"/var/lib/nginx
  install -dm700 "$pkgdir"/var/lib/nginx/proxy

  chmod 750 "$pkgdir"/var/log/nginx
  chown http:log "$pkgdir"/var/log/nginx

  install -d "$pkgdir"/usr/share/nginx
  mv "$pkgdir"/etc/nginx/html/ "$pkgdir"/usr/share/nginx

  install -Dm644 ../logrotate "$pkgdir"/etc/logrotate.d/nginx
  install -Dm644 ../service "$pkgdir"/usr/lib/systemd/system/nginx.service
  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE

  rmdir "$pkgdir"/run

  install -d "$pkgdir"/usr/share/man/man8/
  gzip -9c man/nginx.8 > "$pkgdir"/usr/share/man/man8/nginx.8.gz
}

# vim:set ts=2 sw=2 et:
sha512sums=('b6e59a8379ab8bcd999611808c431045553a3a45e9c67490a79c75ab753216c3c4f469968dd05d7b6404b3d976905f013435e908f324ac5e0d24ab0ff418cb2f'
            '61b7bddc953fb0b0199e79149e9d8a96788851d391010b7ba2a97516986314f58c168669908fa504c0dcb13ffb718c04c940e3aec0f0149be23f41ae80826de7'
            '9ac172be150903c086e6cad0da27363b60e54629ce6a1330d58db0653f89ba301ae07c82441f17b8a5b85d0ff36ba2b6090e11b2a2194760e0dd7fb84cf27ea5'
            'ece7bb0c31232b40c80b03eb51b36c62eec2ec8ad5a454c284bbe5dff47af1cfcfe28dc01727c701a4568e89ae3fcfe69a25d737207f21dae362d1e7647d7d99')