# Maintainer (AUR):  Ainola
# Contributor (Arch): Sven-Hendrik Haase
# Contributor (Arch): Xyne
# Contributor (Arch): Rick Chen (stuffcorpse)
# Contributor (Arch): Jaroslaw Swierczynski
# Contributor (Arch): Roman Kyrylych
# Contributor (Arch): Camille Moncelier

# parabola changes and rationale:
#  - added missing makedepends: mesa

pkgname=nexuiz
pkgver=2.5.2
pkgrel=5
arch=('i686' 'x86_64' 'armv7h')
pkgdesc="Free Fast-paced multiplayer first-person shooter."
url="http://www.alientrap.org/nexuiz/"
license=("GPL")
depends=('alsa-lib' 'libjpeg>=8' 'libxpm' 'libxxf86dga' 'libxxf86vm' 'hicolor-icon-theme' 'sdl')
conflicts=('nexuiz-data')
provides=('nexuiz-data')
makedepends=('mesa')
source=("http://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver//./}.zip" \
        "nexuiz-glx.desktop" "nexuiz-sdl.desktop" \
        "libpng14.patch" "nex-icons.tar.gz")
sha256sums=('a5e27ebcc9775c4a490d0d3536c32e4a8f8f96b038c0b6a78d1823c37a962000'
            'bdeeb0a8eec23122311c8a574dd9a8c8616d352daa285b34b74fac17fb5d5031'
            'bc1827a1677b48d20edc6d297cf465f0c8d511fc3ca829c63946042222d2aee0'
            '327c45a56faa1963fa08a590694fd0c23bed448282f9473c2d483447df9a6e1f'
            '25e478b783bb7f8cff04b7c3e538a82e8ab852d72930277e83d00777d2a7186e')
# Prevent compressing final package
PKGEXT='.pkg.tar'

build(){
    cd "${srcdir}/Nexuiz"
    bsdtar -x -f "sources/enginesource20091001.zip"
    cd darkplaces
    patch -Np1 -i "${srcdir}/libpng14.patch"

    # Build the binaries separately instead to avoid truncated files
    make CPUOPTIMIZATIONS="$CFLAGS" DP_FS_BASEDIR=/usr/share/nexuiz/ DP_LINK_TO_LIBJPEG=1 cl-nexuiz
    make CPUOPTIMIZATIONS="$CFLAGS" DP_FS_BASEDIR=/usr/share/nexuiz/ DP_LINK_TO_LIBJPEG=1 sdl-nexuiz
    make CPUOPTIMIZATIONS="$CFLAGS" DP_FS_BASEDIR=/usr/share/nexuiz/ DP_LINK_TO_LIBJPEG=1 sv-nexuiz
}

package(){
    install -Dm755 "Nexuiz/darkplaces/nexuiz-dedicated" "${pkgdir}/usr/bin/nexuiz-dedicated"
    install -Dm755 "Nexuiz/darkplaces/nexuiz-glx" "${pkgdir}/usr/bin/nexuiz-glx"
    install -Dm755 "Nexuiz/darkplaces/nexuiz-sdl" "${pkgdir}/usr/bin/nexuiz-sdl"
    install -Dm644 "${srcdir}/"*.desktop -t "${pkgdir}/usr/share/applications"

    # Documentation
    install -dm755 "${pkgdir}/usr/share/doc/nexuiz/"
    mv "${srcdir}/Nexuiz/Docs/"* "${pkgdir}/usr/share/doc/nexuiz/"
    find "${pkgdir}/usr/share/doc/nexuiz" -type d -exec chmod 755 {} \;
    find "${pkgdir}/usr/share/doc/nexuiz" -type f -exec chmod 644 {} \;

    # Game Data
    install -dm755 "${pkgdir}/usr/share/nexuiz"
    for dir in data havoc server; do
        mv "${srcdir}/Nexuiz/${dir}" "${pkgdir}/usr/share/nexuiz/"
        find "${pkgdir}/usr/share/nexuiz/${dir}" -type d -exec chmod 755 {} \;
        find "${pkgdir}/usr/share/nexuiz/${dir}" -type f -exec chmod 644 {} \;
    done

    # Remove unneeded cruft
    find "${pkgdir}/usr/share/nexuiz/server" -name "*_windows.bat" -exec rm {} \;
    find "${pkgdir}/usr/share/nexuiz/server" -name "*_mac.sh" -exec rm {} \;

    # Icons
    for size in 16 22 24 32 48 64 128 256 512; do
        install -Dm644 "${srcdir}/nex${size}.png" \
            "${pkgdir}/usr/share/icons/hicolor/${size}x${size}/apps/nexuiz.png"
    done
}