# This is the PKGBUILD for mosquitto, an MQTT broker and example clients

# Maintainer: Tomáš Mládek <tmladek{at}inventati{dt}org> 
# Contributor: Dan Anderson <dan-anderson at cox dptnet>

pkgname=mosquitto
pkgver=1.4
pkgrel=1
pkgdesc="An Open Source MQTT v3.1 Broker"
arch=('i686' 'x86_64' 'arm' 'armv6h' 'armv7h' 'mips64el')
url="http://mosquitto.org/"
depends=('openssl' 'c-ares')
makedepends=('python' 'docbook-xsl' 'c-ares')
license=('custom:EPL1.0' 'custom:EDL1.0')
source=(http://mosquitto.org/files/source/$pkgname-$pkgver.tar.gz{,.asc}
        "$pkgname.service" "$pkgname.install"
        "docbook.patch" "usr_move.patch")
md5sums=('cd879f5964311501ba8e2275add71484'
         'SKIP'
         'a44fa1a85964b7309f5fb6de774aaa07'
         'bfabddbce1d8c856cbb52517a7917d4c'
         '8e1c14e99d7eba210b874e80b5153f0d'
         '89383ee1ce75263949543069e247ecd6')
install=$pkgname.install
validpgpkeys=('A0D6EEA1DCAE49A635A3B2F0779B22DFB3E717B7')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"
  #patch -p1 < ../docbook.patch
#  patch -p1 < ../usr_move.patch
  sed "s,/sbin,/bin,g" -i src/Makefile
}

build() {
  cd "$srcdir/$pkgname-$pkgver"

  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make prefix=/usr DESTDIR="$pkgdir/" install

  # systemd service file
  install -Dm644 "$srcdir/$pkgname.service" "$pkgdir/usr/lib/systemd/system/$pkgname.service"
  echo 'pid_file /run/mosquitto.pid' >> "$pkgdir/etc/mosquitto/mosquitto.conf.example"

  # license files
  install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  install -Dm644 epl-v10 "$pkgdir/usr/share/licenses/$pkgname/EPL-1.0"
  install -Dm644 edl-v10 "$pkgdir/usr/share/licenses/$pkgname/EDL-1.0"
}