# $Id$
# Maintainer: fauno <fauno@parabola.nu>
pkgname=miniupnpd
pkgver=1.8.20130503
pkgrel=3
pkgdesc="Lightweight UPnP IGD daemon"
arch=('i686' 'x86_64' 'mips64el')
url="http://miniupnp.free.fr"
license=('BSD')
backup=(etc/miniupnpd/miniupnpd.conf)
depends=('libnfnetlink' 'iptables>=1.4.3' 'net-tools')
makedepends=('lsb-release')
source=("http://miniupnp.free.fr/files/$pkgname-$pkgver.tar.gz"
        miniupnpd.systemd)
md5sums=('484dbda7c428b2d5f3768500a48d3375'
         '0c3f1777b6c043dd5029092d62896660')

build() {
	cd "$srcdir/$pkgname-$pkgver"

	CONFIG_OPTIONS="--strict --ipv6" make -f Makefile.linux config.h
	make -f Makefile.linux
}

package() {
	cd "$srcdir/$pkgname-$pkgver"
	mkdir -p "$pkgdir/usr/share/man/man8"

	make PREFIX="$pkgdir/" -f Makefile.linux install

	rm -r "${pkgdir}/etc/init.d"

	install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
	install -Dm644 "${srcdir}/miniupnpd.systemd" "${pkgdir}/usr/lib/systemd/system/miniupnpd.service"

	sed -i 's:/s\?bin/iptables:/usr/bin/iptables:
	        s:eth0:"`cat /etc/miniupnpd/miniupnpd.conf | '"awk -F= '/^ext_ifname/ { print \$2 }'"'`":' "${pkgdir}"/etc/miniupnpd/*.sh
	sed -i -e "s/^uuid=[-0-9a-f]*/uuid=00000000-0000-0000-0000-000000000000/
	           s/make genuuid/uuidgen/" "${pkgdir}/etc/miniupnpd/miniupnpd.conf"
        # usrmove
        cd "$pkgdir"
        mv usr/sbin usr/bin
}