# Contributor (Arch): Balló György <ballogyor+arch at gmail dot com>
# Contributor (Arch): Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
# Contributor (Arch): AndyRTR <andyrtr@archlinux.org>
# Contributor (Arch): kiefer <jorgelmadrid@gmail.com>
# Maintainer (Arch): Aaditya Bagga <aaditya_gnulinux@zoho.com>
# Maintainer: David P. <megver83@openmailbox.org>
# Contributor: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=lxdm-consolekit
_pkgname=lxdm
pkgver=0.5.3
pkgrel=4
pkgdesc='LXDM with consolekit support enabled'
arch=('armv7h' 'i686' 'x86_64')
url="https://sourceforge.net/projects/lxdm/"
license=('GPL')
depends=('gtk2' 'xorg-server' 'consolekit')
makedepends=('intltool' 'iso-codes')
optdepends=('gtk-engines: default GTK+ theme'
            'iso-codes: show language names in language chooser'
            'librsvg: display the default background')
conflicts=('lxdm')
provides=('lxdm')
install=$_pkgname.install
backup=('etc/lxdm/lxdm.conf' 'etc/pam.d/lxdm' 'etc/lxdm/Xsession'
        'etc/lxdm/PreLogin' 'etc/lxdm/LoginReady' 'etc/lxdm/PostLogin'
        'etc/lxdm/PostLogout' 'etc/lxdm/PreReboot' 'etc/lxdm/PreShutdown')
source=(https://downloads.sourceforge.net/lxdm/$_pkgname-$pkgver.tar.xz
        git-fixes.patch
        default-config.patch
        lxdm.pam
        Xsession)
sha256sums=('4891efee81c72a400cc6703e40aa76f3f3853833d048b72ec805da0f93567f2f'
            'ca3b225fb85a4e87ebb48e2b1a20f4bab86bf619a9ad927f08fdc819bc435bb4'
            '9d0a942d857b641927ce908dc05802339ada09577e591f7bec2cd7630c46f4be'
            '6f7b8078730c13a33ae8c82334d91f1c394e04cec6e667b2814cf7d3a0722957'
            'c55316e0083c6a8c6fe195e009f271d7cce1da04f04e1640848d76630decfebe')

prepare(){
  cd $_pkgname-$pkgver

  # Apply fixes from git
  patch -Np1 -i ../git-fixes.patch

  # Adjust Arch-specific settings
  patch -Np1 -i ../default-config.patch

  # Use our custom pam and Xsession files
  cp ../lxdm.pam pam/lxdm
  cp ../Xsession data/Xsession

  # Support for pulseaudio
  echo 'test -x /usr/bin/pax11publish && /usr/bin/pax11publish -r' >> data/PostLogout.in
}

build() {
  cd $_pkgname-$pkgver
  ./configure --prefix=/usr --sbindir=/usr/bin --libexecdir=/usr/lib/lxdm \
              --sysconfdir=/etc --localstatedir=/var --with-systemdsystemunitdir=no
  make
}

package() {
  cd $_pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  chmod 644 "$pkgdir/etc/lxdm/lxdm.conf"
}