# Contributor (Arch): Branko Vukelic <bg.branko@gmail.com>
# Maintainer: Márcio Silva <coadde@parabola.nu>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=lprof
pkgver=1.11.4.1
pkgrel=3
arch=(i686 x86_64 mips64el)
pkgdesc="Imaging device calibration tool"
url="http://lprof.sourceforge.net/"
license="GPL"
depends=('qt3' 'lcms>=1.12' 'vigra>=1.3')
makedepends=('python>=1.53' 'scons')
source=(http://downloads.sourceforge.net/lprof/${pkgname}-${pkgver}.tar.gz
        lcms-117.patch)
md5sums=('2177c77c24aa10db9b7681d264735ea9'
         '5ce946c711462428a10116065647c823')

prepare() {
  cd ${pkgname}-${pkgver}
  patch -p0<../lcms-117.patch
  sed -i "s/'tiff'/'tiff','png'/" SConstruct || return 1
  sed -i "s|'moc'|'moc-qt3'|" SConstruct || return 1
  sed -i "s|'uic'|'uic-qt3'|" SConstruct || return 1
  sed -i "s|qtdir, 'lib'|qtdir, 'lib', 'qt3'|
          s|qtdir, 'include'|qtdir, 'include', 'qt3'|
         " SConstruct || return 1
  sed -i "s|qmake|qmake-qt3|
          s|lrelease|lrelease-qt3|
          s|lupdate|lupdate-qt3|
         " {createtrans,comptrans}.sh
  rm -rf scons*
}

build() {
  cd ${pkgname}-${pkgver}
  scons PREFIX=/usr qt_directory=/usr || return 1
}

package() {
  cd ${pkgname}-${pkgver}
  install -d ${pkgdir}/usr
  scons PREFIX=${pkgdir}/usr install
}