# Maintainer (Arch): Daniel Landau <daniel+aur@landau.fi>
# Contributor (Arch): sekret, mail=$(echo c2VrcmV0QHBvc3Rlby5zZQo= | base64 -d)
# Contributor (Arch): mmm
# Contributor (Arch): bslackr <brendan at vastactive dot com>
# Contributor (Arch): Jan "heftig" Steffens <jan.steffens@gmail.com>
# Contributor (Arch): Thomas Dziedzic < gostrc at gmail >
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: bill-auger <bill-auger@programmer.net>


pkgname=lightspark
pkgver=0.8.2
pkgrel=1
pkgdesc="An open source flash player implementation"
arch=('armv7h' 'i686' 'x86_64')
url=http://lightspark.github.io/
license=('LGPL3')

depends=('boost-libs' 'cairo' 'curl' 'desktop-file-utils' 'ffmpeg' 'glew' \
         'glibmm' 'llvm' 'pango' 'rtmpdump' 'sdl2_mixer'                  )
optdepends=('gnash-gtk: Gnash fallback support')
makedepends=('cmake' 'nasm' 'boost')
conflicts=('lightspark-git')

install=lightspark.install
source=(https://github.com/lightspark/lightspark/archive/${pkgver}.tar.gz)
sha256sums=('05595a3085bf76ea5c9723f128dcadead5ccf38e177c3a456901ccee3265548a')


_builddir=${pkgname}-${pkgver}/build


prepare()
{
  cd "${srcdir}"/

  [ -d ${_builddir} ] && rm -rf ${_builddir}/* || mkdir ${_builddir}
}

build()
{
  cd "${srcdir}"/${_builddir}/

  cmake -DCMAKE_INSTALL_PREFIX=/usr         \
        -DCOMPILE_PLUGIN=1                  \
        -DCMAKE_BUILD_TYPE=Release          \
        -DGNASH_EXE_PATH=/usr/bin/gtk-gnash \
        -DAUDIO_BACKEND="pulseaudio sdl"   ..
  make CFLAGS=-Wno-dev
}

package()
{
  cd "${srcdir}"/${_builddir}/

  make DESTDIR="${pkgdir}/" install

  local _boost_ver=$(pacman -S --print-format='%v' boost-libs)
  depends+=("boost-libs>=${_boost_ver}" "boost-libs<$((${_boost_ver%%.*} + 1))")
}