# Maintainer (Arch): Jens Kuske <jenskuske@gmail.com>
# Contributor (Arch): smotocel69 <smotocel69@gmail.com>
# Maintainer: André Silva <emulatorman@parabola.nu>
pkgname=libvdpau-sunxi-git
pkgver=r99.427fa6b
pkgrel=2
pkgdesc="VDPAU driver for Allwinner sunxi SoCs"
arch=('armv7h')
url="https://github.com/linux-sunxi/libvdpau-sunxi"
license=('LGPL')
depends=('libx11' 'libcedrus-git' 'pixman')
makedepends=('git' 'libvdpau')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=("git+https://github.com/linux-sunxi/${pkgname%-git}"
	'50-cedar.rules'
	'50-disp.rules'
	'50-g2d.rules'
	'50-ion.rules'
	'libvdpau.sh'
	'sunxi.cedar.conf')
md5sums=('SKIP'
         'd606a1d188034616875eb82651a7abcb'
         '728532c6c8b3581c0b3e94ff8cd8a568'
         '17f989c2db2809cae9dd9bcf2b5cd2c1'
         '7b8147257ca77a4bbbcdaedffd6c431b'
         'ed91a5c6cde4cc9a3ee93d804c71897a'
         'a4c1f739fc8961722a2d7ace5852cfc0')

pkgver() {
	cd ${pkgname%-git}
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	cd ${pkgname%-git}
	make
}

package() {
	cd ${pkgname%-git}
	make DESTDIR="$pkgdir/" install
	install -dm755 $pkgdir/etc/{udev/rules.d,{modules-load,profile}.d}
	install -Dm644 $srcdir/50-{cedar,disp,g2d,ion}.rules $pkgdir/etc/udev/rules.d
	install -Dm755 $srcdir/libvdpau.sh $pkgdir/etc/profile.d
	install -Dm644 $srcdir/sunxi.cedar.conf $pkgdir/etc/modules-load.d
}