# $Id$
# Contributor (Arch): Felix Yan <felixonmars@gmail.com>
# Contributor (Arch): Rainy <rainylau(at)gmail(dot)com>
# Contributor (Arch): Lee.MaRS <leemars at gmail dot com>
# Contributor (Arch): Daniel J Griffiths <ghost1227@archlinux.us>
# Contributor (Arch): Brad Fanella <bradfanella@archlinux.us>
# Maintainer : Parabola GNU / Linux-libre Aurélien Desbrières <aurelien@cwb.io>

_pkgbase=ibus
pkgname=lib$_pkgbase
pkgver=1.4.99.20121109
pkgrel=1
pkgdesc="Library for Next Generation Input Bus for Linux"
arch=('i686' 'x86_64' 'mips64el')
url="http://ibus.googlecode.com"
license=('LGPL')
depends=('glib2')
makedepends=('gobject-introspection' 'dconf' 'iso-codes' 'intltool' 'gtk2' 'gtk3')
options=('!libtool')
provides=("$_pkgbase=$pkgver")
conflicts=('ibus')
source=(http://ibus.googlecode.com/files/${_pkgbase}-${pkgver}.tar.gz)

build() {
  cd "$srcdir/${_pkgbase}-${pkgver}"
  export PYTHON=python2
  ./configure \
    --prefix=/usr \
    --libexecdir=/usr/lib/ibus \
    --sysconfdir=/etc \
    --disable-gconf \
    --enable-dconf \
    --disable-memconf \
    --enable-ui
  make
}

package() {
  cd "$srcdir/${_pkgbase}-${pkgver}"
  make DESTDIR="${pkgdir}" install-pkgconfigDATA
  cd src
  make DESTDIR="${pkgdir}" install
}
md5sums=('be482479357210283e91a47f43a0a0fe')