# Maintainer (AUR): gato_lento <vukk.euob at gmail>
# Based on helm-git PKGBUILD by: Christopher Arndt <aur -at- chrisarndt -dot- de>
# Contributor: André Silva <emulatorman@hyperbola.info>

# parabola changes and rationale:
#  - changed tarball name to reduce chance of collisions
#  - added missing depends: libxinerama jack libxcursor
#  - added patch to fix compile error against recent glibc

pkgname='helm'
pkgver=0.9.0
pkgrel=3
pkgdesc='a cross-platform, polyphonic synthesizer, available standalone and as an LV2 plugin'
arch=('x86_64' 'i686' 'armv7h')
url='http://tytel.org/helm/'
license=('GPL')
groups=('lv2-plugins')
depends=('alsa-lib' 'freetype2' 'mesa' 'lv2' 'libxinerama' 'jack' 'libxcursor')
conflicts=('helm-git')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/mtytel/helm/archive/v${pkgver}.tar.gz"
        "sigemptyset.patch")
sha256sums=('4004c11fd1d773cc2a12adb5336873bc86c5ecbd370b8da2820fed6ef5ec58ad'
            '66c442780c36b5a17c73be7f76b46ba9261e69591d15be4607c90214852b1454')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  patch -Np1 -i "$srcdir"/sigemptyset.patch

  for build in standalone/builds/linux builds/linux/VST builds/linux/LV2; do
    sed -i -e 's|JUCE_INCLUDE_PNGLIB_CODE=0|JUCE_INCLUDE_PNGLIB_CODE=1|g' \
      "${build}/Makefile"
  done
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  CXXFLAGS="${CXXFLAGS} -DHAVE_LROUND -Wno-error"
  make PREFIX="/usr" standalone lv2
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  CXXFLAGS="${CXXFLAGS} -DHAVE_LROUND -Wno-error"
  make DESTDIR="$pkgdir" install_standalone install_lv2
}