# Maintainer (Parabola): Márcio Silva <coadde@lavabit.com>

pkgname=ha-glue
_pkgname=${pkgname:3}
pkgver=1.0.11
pkgrel=3
pkgdesc='A set of libraries, tools and utilities suitable for the Heartbeat/Pacemaker cluster stack'
arch=(
  i686
  x86_64
  mips64el
)
url=http://linux-ha.org/wiki/Cluster_${_pkgname^}
license=(
  GPL2
  LGPL2.1
)
depends=(
  curl
  glib2
  libaio
  libesmtp
  libxml2
  net-snmp
  python
  util-linux
)
optdepends=(
  lynx
  net-tools
  openssh
  #valgrind
  #w3m
)
makedepends=(
  help2man
  libxslt
  #lynx
  net-tools
  openssh
  #valgrind
  #w3m
)
install=$pkgname.install
source=(
  http://hg.linux-ha.org/$_pkgname/archive/$_pkgname-$pkgver.tar.bz2
  ha-log.service
)
sha512sums=(
  35ac8ac555c39f24c11e3a768cc50eba051fe617edf4cdc0429dac73f45a472f144cfe6ec5faff575606f2b04ff76a2f732556d848b61410c2683d93ba928413
  9252472a6d7a1bbad765c63becdec4064d882b1eb98abdf27833a6e06d8750f06663b2460d32a4c72d04f10a7480ef0a2093b8a18b4d1fc62a989cde54ee056a
)

prepare() {
  cd $srcdir/Reusable-Cluster-Components-$_pkgname--$_pkgname-$pkgver
  sed -i 's|AM_CONFIG_HEADER|AC_CONFIG_HEADERS|' configure.ac
}

build() {
  cd $srcdir/Reusable-Cluster-Components-$_pkgname--$_pkgname-$pkgver
  ./autogen.sh
  ./configure --prefix=/usr\
    --enable-fatal-warnings=no\
    --libdir=/usr/lib\
    --localstatedir=/var\
    --sysconfdir=/etc\
    --with-daemon-group=haclient\
    --with-daemon-user=hacluster
  make
}

package() {
  cd $srcdir/Reusable-Cluster-Components-$_pkgname--$_pkgname-$pkgver
  setarch $CARCH make DESTDIR=$pkgdir install

  install -d $pkgdir/usr/lib/systemd/system
  install -Dm644 $srcdir/ha-log.service $pkgdir/usr/lib/systemd/system
}

# vim:set ts=2 sw=2 et: