# Maintainer: Márcio Silva <coadde@parabola.nu>
# Maintainer (Arch): Daniel Isenmann <daniel@archlinux.org>

_pkgname=gegl
pkgname=gegl-git
pkgver=r6711.bca30ea
pkgrel=1
pkgdesc="Graph based image processing framework"
arch=('i686' 'x86_64' 'armv7h')
url="http://www.gegl.org/"
license=('GPL3' 'LGPL3')
depends=('babl' 'libspiro' 'json-glib')
makedepends=('intltool' 'ruby' 'lua' 'libopenraw' 'openexr' 'mesa' 'glu' 'ffmpeg' 'librsvg'
             'jasper' 'exiv2' 'vala' 'python2' 'suitesparse' 'git')
optdepends=('libopenraw: openraw plugin'
            'openexr: openexr plugin'
            'ffmpeg: ffmpeg plugin'
            'suitesparse: matting-levin plugin'
            'librsvg: svg plugin'
            'jasper: jasper plugin')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=(${_pkgname}-${pkgver}::git+git://git.gnome.org/${_pkgname}.git)
sha256sums=('SKIP')

pkgver() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  mkdir path
  ln -s /usr/bin/python2 path/python

  cd ${_pkgname}-${pkgver}
}

build() {
  export PATH="$srcdir/path:$PATH" PYTHON=/usr/bin/python2
  cd ${_pkgname}-${pkgver}
  ./autogen.sh
  ./configure  --prefix=/usr  --with-sdl --with-librsvg \
    --with-libavformat --with-jasper --disable-docs

  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

check() {
  export PATH="$srcdir/path:$PATH" PYTHON=/usr/bin/python2
  cd ${_pkgname}-${pkgver}
  make -k check || :
}

package() {
  export PATH="$srcdir/path:$PATH" PYTHON=/usr/bin/python2
  cd ${_pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
}