# Maintainer: Andreas Grapentin <andreas@grapentin.org>

pkgname=gcc-gcj-ecj

pkgver=4.9
pkgrel=4.parabola1
arch=(any)

pkgdesc="A fork of the Eclipse Java bytecode compiler for GCJ"
url="http://gcc.gnu.org/java/"
license=(EPL)

makedepends=(eclipse-ecj java-environment)
depends=(gcc6-gcj)
provides=(eclipse-ecj)
conflicts=(eclipse-ecj)

source=("ftp://sourceware.org/pub/java/ecj-$pkgver-source.tar.bz2"
        "https://git.eclipse.org/c/jdt/eclipse.jdt.core.git/snapshot/R4_3_1.tar.gz"
        "ecj1")
sha256sums=('a48a8bfc419fab20646c49069ae2e0c07b4e73fc56572ac3b7e0151a0388f1c5'
            'affb39ca4f5fab6800846e4279fcd0684ddd3753a3bde475e6505f715af9ec61'
            '3dcf27b250ff7766a9240159b30b4eb5bf8544da93984154643c3068c5dca2d4')
noextract=("ecj-$pkgver-source.tar.bz2")

prepare() {
  mkdir -p $pkgname-$pkgver
  cd $pkgname-$pkgver

  tar -xf ../ecj-$pkgver-source.tar.bz2
  mv ../R4_3_1.tar.gz .

  make checkout
}

build() {
  cd $pkgname-$pkgver

  make compile
  make ecj.jar ecj-source.tar.bz2
}

package() {
	install -D -m644 $srcdir/$pkgname-$pkgver/ecj.jar $pkgdir/usr/share/java/eclipse-ecj.jar
	install -D -m755 $srcdir/ecj1 $pkgdir/usr/bin/ecj1
}