# Maintainer (AUR):  Andrew O'Neill <andrew at meanjollies dot com>
# Contributor (AUR): poisonby <poisonby@tutanota.com>
# Contributor (AUR): Jason Scurtu (scujas) <jscurtu@gmail.com>
# Contributor (AUR): Marcin Tydelski <marcin.tydelski@gmail.com>
# Contributor (AUR): Jan Lukas Gernert (JeanLuc) <https://launchpad.net/~eviltwin1>

# parabola changes and rationale:
#  - added install file to update icon cache

pkgname=feedreader
pkgver=2.0.2
pkgrel=3
pkgdesc="FeedReader is a modern desktop application designed to complement existing web-based RSS accounts."
arch=('i686' 'x86_64' 'armv7h')
url="https://github.com/jangernert/FeedReader"
license=('GPL3')
conflicts=("$pkgname-git")
depends=('sqlite3' 'gtk3' 'webkit2gtk' 'libnotify' 'libsoup' 'libgee' 'json-glib' 'libsecret' 'libpeas' 'gnome-online-accounts' 'curl')
makedepends=('vala' 'gobject-introspection' 'cmake')
install="feedreader.install"
source=("$url/archive/v$pkgver.tar.gz"
        "$pkgname.patch")
sha256sums=('949262912bc07f8d1ec72dfa1bbeafb0ed1cea992589e1ee5901e0630c714261'
            '6a13326630678db6f9de94adcd3e289dc7dba2e656c75967868c0a23ba6e653e')

prepare() {
  cd FeedReader-$pkgver

  patch -p1 -i ../$pkgname.patch
}

build() {
  cd FeedReader-$pkgver

  mkdir build
  cd build

  cmake \
	  -DCMAKE_INSTALL_PREFIX=/usr \
	  -DGSETTINGS_COMPILE=OFF \
	  -DCMAKE_INSTALL_LIBDIR=lib \
	  ..
  make
}

package() {
  cd FeedReader-$pkgver/build

  make DESTDIR=$pkgdir install
}