# Maintainer (Manjaro): artoo <artoo@manjaro.org>
# Contributor (Manjaro): Philip Müller <philm|manjaro|org>
# Contributor (Manjaro): Dave Reisner <dreisner@archlinux.org>
# Contributor (Manjaro): Tom Gundersen <teg@jklm.no>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

_spkgrel=8
_repo=https://repo.parabola.nu

pkgbase=eudev-systemdcompat
pkgname=('eudev-systemd' 'libeudev-systemd')
pkgver=232
pkgrel=2.parabola1
arch=('i686' 'x86_64' 'armv7h')
license=('GPL2')
groups=('base-openrc')
url="http://www.freedesktop.org/wiki/Software/systemd"
source_i686=("$_repo/libre/os/i686/libsystemd-standalone-$pkgver-${_spkgrel}.parabola1-i686.pkg.tar.xz"
             "$_repo/libre/os/i686/systemd-$pkgver-${_spkgrel}.parabola1-i686.pkg.tar.xz")
source_x86_64=("$_repo/libre/os/x86_64/libsystemd-standalone-$pkgver-${_spkgrel}.parabola1-x86_64.pkg.tar.xz"
               "$_repo/libre/os/x86_64/systemd-$pkgver-${_spkgrel}.parabola1-x86_64.pkg.tar.xz")
source_armv7h=("$_repo/libre/os/armv7h/libsystemd-standalone-$pkgver-${_spkgrel}.parabola1-armv7h.pkg.tar.xz"
               "$_repo/libre/os/armv7h/systemd-$pkgver-${_spkgrel}.parabola1-armv7h.pkg.tar.xz")
sha256sums_i686=('bac6ec8f3d591cb8eb9567a5d7a3ca71954ca0b9fac227df6073a5ed47df7e66'
                 '6ffc92f6eb6b8d33dbf8d02e89653d9e505e0f4fd224a693c1033abd2f0b2456')
sha256sums_x86_64=('00599052da82530fafd5ead1ddc88801198a3d73af204a46d2555bbb694dac82'
                   'a3878ea1633a63b712922d3beb82fc382cd0e4261c786ec530f266a0f8e55911')
sha256sums_armv7h=('6179bce7c3ac699becadb054353d40080f25bc88c07ae2affcf490665661151e'
                   'fa0f31a0e6b563468301f535a14cf970ba38b8abfb56163b71038fdcfa76dd22')

package_eudev-systemd() {
    pkgdesc="systemd-sysuser and systemd-tmpfiles binary; systemd compatibility package"
    provides=("systemd=${pkgver}" "systemd-tools=${pkgver}")
    depends=('eudev' 'libseccomp')
    conflicts=('systemd-tools' 'systemd' 'eudev-systemdcompat')
    replaces=('eudev-systemdcompat')

    install -d "$pkgdir"/usr/{bin,lib/systemd}
    for f in usr/bin/systemd-sysusers;do     #{systemd-tmpfiles,systemd-sysusers};do
        mv -v $f "$pkgdir"/usr/bin
    done
    for f in usr/lib/systemd/libsystemd-shared*.so*;do
        mv -v $f $pkgdir/usr/lib/systemd
    done
}

package_libeudev-systemd() {
    pkgdesc="systemd client libraries without udev; systemd compatibility package"
    provides=("libsystemd=${pkgver}" 'libsystemd.so')
    depends=('glibc' 'libcap' 'libgcrypt' 'lz4' 'xz' 'libeudev')
    conflicts=('libsystemd' 'libsystemd-standalone' 'eudev-systemdcompat')
    replaces=('eudev-systemdcompat')

    install -d $pkgdir/usr/lib
    for f in usr/lib/libsystemd*.so*;do
        mv -v $f $pkgdir/usr/lib
    done
}