# Maintainer (Artix): artoo <artoo@manjaro.org>
# Contributor (Arch): Jan de Groot <jgc@archlinux.org>
# Contributor (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor (Arch): Tom Gundersen <teg@jklm.no>
# Contributor (Arch): Link Dupont <link@subpop.net>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

_pkgname=dbus
pkgname=dbus-elogind
pkgver=1.12.2
pkgrel=1
pkgdesc="Freedesktop.org message bus system"
url="https://wiki.freedesktop.org/www/Software/dbus/"
arch=(i686 x86_64 armv7h)
license=(GPL custom)
provides=('libdbus' "dbus=$pkgver" "dbus-x11=$pkgver")
conflicts=('libdbus' 'dbus' 'dbus-x11')
depends=('libx11' 'expat' 'libelogind')
makedepends=('eudev' 'elogind' 'xmlto' 'docbook-xsl' 'python' 'yelp-tools' 'doxygen' 'git' 'autoconf-archive' 'graphviz')
optdepends=('dbus-openrc: dbus initscript')
_commit=0f0968336b9711349023e1d41f075b2bccf7c20b  # tags/dbus-1.12.2^0
source=("git+https://anongit.freedesktop.org/git/dbus/dbus#commit=$_commit"
        'dbus.sysusers'
        'dbus-enable-elogind.patch')
sha256sums=('SKIP'
           '1ce179ba3a92ad34941d8ac7f53d01d42cbc91d43ada1136492b78c10b5d693d'
           'faffcaa5b295f49fcedeed2c9ece5298949096be3062fd99a4bf1a6ac3ad1ea0')
validpgpkeys=('DA98F25C0871C49A59EAFF2C4DE8FF2A63C7CC90'  # Simon McVittie <simon.mcvittie@collabora.co.uk>
              '3C8672A0F49637FE064AC30F52A43A1E4B77B059') # Simon McVittie <simon.mcvittie@collabora.co.uk>

prepare() {
  cd $_pkgname
  patch -Np 1 -i ${srcdir}/dbus-enable-elogind.patch
  # Reduce docs size
  printf '%s\n' >>Doxyfile.in \
    HAVE_DOT=yes DOT_IMAGE_FORMAT=svg INTERACTIVE_SVG=yes
  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd $_pkgname
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --libexecdir=/usr/lib/dbus-1.0 \
    --with-dbus-user=dbus \
    --with-system-pid-file=/run/dbus/pid \
    --with-system-socket=/run/dbus/system_bus_socket \
    --with-console-auth-dir=/run/console/ \
    --enable-inotify \
    --enable-elogind \
    --disable-static \
    --disable-verbose-mode \
    --disable-asserts \
    --enable-x11-autolaunch \
    --enable-elogind \
    --without-systemdsystemunitdir \
    --disable-systemd \
    --disable-user-session
  make
}

check() {
  cd $_pkgname
  make check
}

package() {
  cd $_pkgname

  make DESTDIR="$pkgdir" install

  rm -r "$pkgdir/var/run"

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$_pkgname/COPYING"

  # sysusers
  install -Dm644 "$srcdir/dbus.sysusers" "$pkgdir/usr/lib/sysusers.d/dbus.conf"

  # Remove docs
  rm -r "$pkgdir/usr/share/doc"
}