# Maintainer (Arch): Ivan Shapovalov <intelfx100@gmail.com>
# Contributor (Arch): goodmen <goodmenzy@gmail.com>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Maintainer: fauno <fauno@kiwwwi.com.ar>
# Contributor: Márcio Silva <coadde@parabola.nu>

_pkgname=crosstool-ng
pkgname=crosstool-ng-git
pkgver=1.22.0.r21.g2d3c70d
_gitver=2d3c70dd3ddc5a569c0fa1a833fd5920029b5794
pkgrel=1.parabola1
pkgdesc='Versatile cross-toolchain generator, with Linux-libre kernel support'
arch=('i686' 'x86_64')
url='http://crosstool-ng.org/'
license=('GPL2')
depends=('make' 'gperf' 'wget')
makedepends=('git' 'help2man')
options=('!makeflags')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=(git://github.com/crosstool-ng/crosstool-ng#commit=$_gitver
        ctng-libre.patch)

pkgver() {
  cd $_pkgname
  git describe --long --tags | sed 's/^crosstool-ng-//;s/-/.r/;s/-/./'
}

prepare() {
  cd $_pkgname
  patch -Np1 -i ../ctng-libre.patch
}

build() {
  cd $_pkgname
  ./bootstrap
  ./configure --prefix=/usr
  make
}

package() {
  cd $_pkgname
  make DESTDIR="$pkgdir" install
  install -Dm644 ct-ng.comp "$pkgdir"/usr/share/bash-completion/completions/ct-ng
}
sha256sums=('SKIP'
            '75e06ee8e4cb2629564604498796240cbe57219bd235cade6b6982b7b0836136')