# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>
# Maintainer (AUR): Ivy Foster <joyfulgirl@archlinux.us>
# Maintainer (AUR): Stefan Husmann <stefan-husmann@t-online.de>
# Contributor (AUR): Heeru Kiyura <M8R-p9i5nh@mailinator.com>

pkgname=conkeror
pkgver=1.0pre.git140428.1.git25
_gitver='commit=c5e640d874c65762c082430b42207bcafb58fda6'
pkgrel=1
pkgdesc="A highly programmable web browser based on Mozilla XULRunner."
arch=('i686' 'x86_64')
url="http://conkeror.org/"
license=('MPL1.1' 'GPL2' 'LGPL2.1')
depends=('xulrunner' 'desktop-file-utils')
install=conkeror.install

source=("https://repo.parabolagnulinux.org/other/$pkgname/$pkgname-$pkgver.tar.gz"
        'conkeror.sh')
md5sums=('a59ddc563eb8de7e8be6465aa023102d'
         '11c6c76a2639254754b34a542f1965a1')

mkdepends=('git')
mksource=("$pkgname-$pkgver::git://repo.or.cz/conkeror.git#${_gitver}")
mkmd5sums=('SKIP')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  install -d "$pkgdir"/usr/{bin,share/{man/man1,applications}}

  cp -a . "$pkgdir"/usr/share/$pkgname

  ln -srT "$pkgdir"/usr/share/$pkgname/contrib/man/conkeror.1 \
          "$pkgdir"/usr/share/man/man1/$pkgname.1
  ln -srT "$pkgdir"/usr/share/$pkgname/debian/conkeror.desktop \
          "$pkgdir"/usr/share/applications/$pkgname.desktop
  ln -srT "$pkgdir"/usr/share/$pkgname/conkeror-spawn-helper \
          "$pkgdir"/usr/bin/conkeror-spawn-helper

  install -Dm755 "$srcdir"/conkeror.sh "$pkgdir"/usr/bin/$pkgname
}