# Maintainer: bill-auger <bill-auger@programmer.net>


pkgname=calamares
pkgver=3.2.4
pkgrel='parabola1'
pkgdesc='Distribution-independent installer framework - Parabola edition'
arch=('i686' 'x86_64')
url=https://calamares.io/
license=('GPL')

_latest_version() { pacman -Si $1 | awk '$1=="Version" { sub (/-.*/, "" , $3) ; print $3 }' | sort -V | tail -n 1 ; }
_runtime_couplings=("boost-libs=$(_latest_version 'boost')"
                    "icu=$(_latest_version 'icu')"
                    "kpmcore=$(_latest_version 'kpmcore')"
                    "qt5-base=$(_latest_version 'qt5-base')")
_build_couplings=("boost=$(_latest_version 'boost')")
depends=(${_runtime_couplings[@]} 'ckbcomp' 'dmidecode' 'gptfdisk' 'hwinfo' 'kconfig'
         'kcoreaddons' 'ki18n' 'kparts' 'libpwquality' 'os-prober' 'polkit-qt5' 'python'
         'solid' 'qt5ct' 'qt5-svg' 'yaml-cpp')
makedepends=(${_build_couplings[@]} 'extra-cmake-modules' 'git' 'kservice' \
             'kwindowsystem' 'plasma-framework' 'qt5-tools')

_git_tag="v${pkgver}-${pkgrel%%.*}"
_build_dir=${pkgname}/build
source=(git+https://git.parabola.nu/${pkgname}.git#tag=${_git_tag})
sha256sums=('SKIP')


build()
{
  mkdir -p ${srcdir}/${_build_dir}
  cd       ${srcdir}/${_build_dir}

  cmake -DCMAKE_BUILD_TYPE=Debug                                                       \
        -DCMAKE_INSTALL_PREFIX=/usr                                                    \
        -DCMAKE_INSTALL_LIBDIR=lib                                                     \
        -DSKIP_MODULES="contextualprocess dracut dracutlukscfg dummycpp dummyprocess   \
                        dummypython  dummypythonqt fsresizer initramfs initramfscfg    \
                        interactiveterminal license openrcdmcryptcfg plymouthcfg       \
                        preservefiles rawfs removeuser shellprocess tracking webview" ..
  make
}

package()
{
  cd ${srcdir}/${_build_dir}

  make DESTDIR=${pkgdir} install
}