# Maintainer: bill-auger <bill-auger@programmer.net>


pkgname=calamares
pkgver=3.2.4
pkgrel='parabola3'
pkgdesc='Distribution-independent installer framework - Parabola edition'
arch=('i686' 'x86_64')
url=https://calamares.io/
license=('GPL')

depends=('ckbcomp' 'dmidecode' 'gptfdisk' 'hwinfo' 'kconfig' 'kcoreaddons' 'ki18n' \
         'kparts' 'libpwquality' 'os-prober' 'polkit-qt5' 'python' 'solid' 'qt5ct' \
         'qt5-svg' 'yaml-cpp'                                                      )
makedepends=('boost' 'extra-cmake-modules' 'git' 'kservice' 'kwindowsystem' \
             'plasma-framework' 'qt5-tools'                                 )

_git_tag=v${pkgver}-${pkgrel%%.*}
_build_dir=${pkgname}/build
source=(git+https://git.parabola.nu/${pkgname}.git#tag=${_git_tag})
sha256sums=('SKIP')


_version_constraint() # (_dep_pkgname)
{
  _dep_pkgname=$1
  _version=$(pacman -S --print-format='%v' ${_dep_pkgname})
  _version_inc=${_version%.*}.$(( ${_version##*.} + 1 ))

  echo -n " ${_dep_pkgname}>=${_version} ${_dep_pkgname}<${_version_inc} "
}

build()
{
  mkdir -p "${srcdir}/${_build_dir}"
  cd       "${srcdir}/${_build_dir}"

  cmake -DCMAKE_BUILD_TYPE=Debug                                                       \
        -DCMAKE_INSTALL_PREFIX=/usr                                                    \
        -DCMAKE_INSTALL_LIBDIR=lib                                                     \
        -DSKIP_MODULES="contextualprocess dracut dracutlukscfg dummycpp dummyprocess   \
                        dummypython  dummypythonqt fsresizer initramfs initramfscfg    \
                        interactiveterminal license openrcdmcryptcfg plymouthcfg       \
                        preservefiles rawfs removeuser shellprocess tracking webview" ..
  make
}

package()
{
  depends+=( $(_version_constraint 'boost-libs') \
             $(_version_constraint 'icu'       ) \
             $(_version_constraint 'kpmcore'   ) \
             $(_version_constraint 'qt5-base'  ) )

  cd "${srcdir}/${_build_dir}"

  make DESTDIR=${pkgdir} install
}