# Maintainer: bill-auger <bill-auger@programmer.net>


pkgname=calamares
pkgver=3.2.8
pkgrel='parabola2'
pkgdesc='Distribution-independent installer framework - Parabola edition'
arch=('i686' 'x86_64')
url=https://calamares.io/
license=('GPL')

depends=('boost-libs' 'ckbcomp' 'dmidecode' 'gptfdisk' 'hwinfo' 'icu' 'kconfig' \
         'kcoreaddons' 'ki18n' 'kparts' 'kpmcore' 'libpwquality' 'os-prober'    \
         'polkit-qt5' 'python' 'solid' 'qt5-base' 'qt5ct' 'qt5-svg' 'yaml-cpp'  )
makedepends=('boost' 'extra-cmake-modules' 'git' 'kservice' 'kwindowsystem' \
             'plasma-framework' 'qt5-tools'                                 )

_git_tag=v${pkgver}-${pkgrel%%.*}
_build_dir=${pkgname}/build
source=(git+https://git.parabola.nu/${pkgname}.git#tag=${_git_tag})
sha256sums=('SKIP')


_version_constraint() # (dep_pkgname)
{
  local dep_pkgname=$1
  local version=$(pacman -S --print-format='%v' ${dep_pkgname} | tail -n 1)
  version=${version%-*}
  version_inc=${version%.*}.$(( ${version##*.} + 1 ))

  echo -n "${dep_pkgname}>=${version}" "${dep_pkgname}<${version_inc}"
}

prepare()
{
  sed -i "s|_BUILD_DATE_|$(date +%Y.%m)|" ${srcdir}/${pkgname}/src/branding/parabola/branding.desc
}

build()
{
  mkdir -p "${srcdir}/${_build_dir}"
  cd       "${srcdir}/${_build_dir}"

  cmake -DCMAKE_BUILD_TYPE=Release                                                   \
        -DCMAKE_INSTALL_PREFIX=/usr                                                  \
        -DCMAKE_INSTALL_LIBDIR=lib                                                   \
        -DSKIP_MODULES="contextualprocess dracut dracutlukscfg dummycpp dummyprocess \
                        dummypython dummypythonqt fsresizer initramfs initramfscfg   \
                        interactiveterminal license networkcfg openrcdmcryptcfg      \
                        packages plymouthcfg preservefiles rawfs removeuser          \
                        shellprocess tracking unpackfs webview"                      ..
  make
}

package()
{
  depends+=( $(_version_constraint 'boost-libs') \
             $(_version_constraint 'icu'       ) \
             $(_version_constraint 'kpmcore'   ) \
             $(_version_constraint 'qt5-base'  ) )

  cd "${srcdir}/${_build_dir}"

  make DESTDIR=${pkgdir} install
}