# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Contributor (Arch): Eric Bélanger <eric@archlinux.org>
# Contributor: Jesús E. <heckyel@parabola.nu>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Luke R. <g4jc@openmailbox.org>

pkgname=webkit2gtk

pkgver=2.18.3
pkgrel=3.nonprism2
arch=(i686 x86_64 armv7h)

pkgdesc="GTK+ Web content engine library, without geoclue2 support"
url="https://webkitgtk.org/"
license=(custom)

depends=(libxt libxslt enchant libsoup gst-plugins-base-libs gst-plugins-bad
         libsecret libwebp harfbuzz-icu gtk3 libnotify hyphen)
makedepends=(gtk2 gperf gobject-introspection ruby gtk-doc cmake python python2 ninja)
optdepends=('gtk2: Netscape plugin support'
            'gst-plugins-base: free media decoding'
            'gst-plugins-good: media decoding'
            'gst-libav: nonfree media decoding')
options=(!emptydirs)

source=("https://webkitgtk.org/releases/webkitgtk-${pkgver}.tar.xz"{,.asc})
sha256sums=('e15420e1616a6f70f321541d467af5ca285bff66b1e0fa68a01df3ccf1b18f9e'
            'SKIP')
validpgpkeys=('D7FCF61CF9A2DEAB31D81BD3F3D322D0EC4582C3')

prepare() {
  mkdir build
  cd webkitgtk-$pkgver

  sed -i '1s/python$/&2/' Tools/gtk/generate-gtkdoc
  rm -r Source/ThirdParty/gtest/
}

build() {
  cd build
  # temporarily disabling GTKDOC build, it breaks compilation on x86_64
  cmake -G Ninja -DPORT=GTK -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_SKIP_RPATH=ON -DCMAKE_INSTALL_PREFIX=/usr \
        -DLIB_INSTALL_DIR=/usr/lib -DLIBEXEC_INSTALL_DIR=/usr/lib/webkit2gtk-4.0 \
        -DUSE_GEOCLUE2=OFF -DENABLE_GEOLOCATION=OFF \
        -DENABLE_GTKDOC=OFF -DPYTHON_EXECUTABLE=/usr/bin/python2 ../webkitgtk-$pkgver

  if [[ "$CARCH" =~ ^arm*|^aarch64$ ]]; then
    # strip -O3 from cmake generated makefiles
    find ./ -type f -exec sed -i -e 's/-O3//g' {} \;
  fi

  ninja
}

package() {
  cd build
  DESTDIR="$pkgdir" ninja install

  cd ../webkitgtk-$pkgver/Source
  while IFS= read -d $'\0' -r _f; do
    echo "### $_f ###"; cat "$_f"; echo
  done < <(find . -name 'COPYING*' -or -name 'LICENSE*' -print0) \
    | install -Dm644 /dev/stdin "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}