# $Id$
# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor (Arch): Eric Bélanger <eric@archlinux.org>
# Contributor: Andreas Grapentin <andreas@grapentin.org>
# Contributor: Jesús E. <heckyel@parabola.nu>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Luke R. <g4jc@openmailbox.org>
# Contributor: Freemor <freemor@fremor.ca>

# parabola changes and rationale:
#  - remove geoclue2 support

pkgname=webkit2gtk
pkgver=2.28.2
pkgrel=2
pkgrel+=.nonprism1
pkgdesc="GTK+ Web content engine library"
pkgdesc+=", without geoclue2 support"
arch=(x86_64)
arch+=(i686 armv7h)
url="https://webkitgtk.org/"
license=(custom)
depends=(libxt libxslt enchant gst-plugins-base-libs libsecret libwebp openjpeg2
         harfbuzz-icu gtk3 libnotify hyphen woff2 libwpe wpebackend-fdo
	 bubblewrap xdg-dbus-proxy)
makedepends=(gperf gobject-introspection ruby gtk-doc cmake python)
optdepends=('gst-plugins-base: free media decoding'
            'gst-plugins-good: media decoding'
            'gst-plugins-bad: media decoding'
            'gst-libav: nonfree media decoding')
source=(https://webkitgtk.org/releases/webkitgtk-${pkgver}.tar.xz{,.asc})
sha256sums=('b9d23525cfd8d22c37b5d964a9fe9a8ce7583042a2f8d3922e71e6bbc68c30bd'
            'SKIP')
validpgpkeys=('D7FCF61CF9A2DEAB31D81BD3F3D322D0EC4582C3'
	      '5AA3BC334FD7E3369E7C77B291C559DBE4C9123B')

# disable SSE2 on 486 and 686
if [ "$CARCH" = 'i486' -o "$CARCH" = 'i686' ]; then
        source+=('webkitgtk-2.24.2-no-sse2.patch')
        sha256sums+=('e95391eceeb29d0ebc57d6b867afd7cd95ed92683edeb28c6a7a5048b5a9b85b')

        eval "$(
          declare -f prepare | \
            sed '
              /cd.*/a patch -p1 < ../webkitgtk-2.24.2-no-sse2.patch
            '
        )"
fi

# work around broken generated makefiles resulting in
# "make[2]: *** No rule to make target 'JavaScriptCore-4.0.gir', needed by 'WebKit2-4.0.gir'.  Stop."
eval "$(
  declare -f build | \
    sed '
      /cmake --build build/a \
        cd build && make JavaScriptCore-4-gir && cd .. \
        cmake --build build
      s/\(cmake --build build\)/\1 || true/g
    '
)"



prepare() {
  cd webkitgtk-$pkgver
#  patch -Np1 -i ../icu65.patch # from PLD Linux
}

build() {
  cmake -Hwebkitgtk-$pkgver -Bbuild \
    -DPORT=GTK \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_SKIP_RPATH=ON \
    -DENABLE_GTKDOC=ON \
    -DLIBEXEC_INSTALL_DIR=/usr/lib \
    -DLIB_INSTALL_DIR=/usr/lib \
    -DENABLE_GEOLOCATION=OFF
  cmake --build build
}

check() {
  : cmake --build build --target tests
}

package() {
  depends+=(libwpe-1.0.so libWPEBackend-fdo-1.0.so)
  provides+=(libjavascriptcoregtk-4.0.so libwebkit2gtk-4.0.so)

  DESTDIR="$pkgdir" cmake --build build --target install

  cd webkitgtk-$pkgver
  find Source -name 'COPYING*' -or -name 'LICENSE*' -print0 | sort -z |
    while IFS= read -d $'\0' -r _f; do
      echo "### $_f ###"
      cat "$_f"
      echo
    done |
    install -Dm644 /dev/stdin "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}