# $Id: PKGBUILD 289009 2017-02-15 15:43:20Z jgc $
# Contributor (Arch): Eric Bélanger <eric@archlinux.org>
# Contributor: André Silva <emulatorman@riseup.net>
# Contributor: Luke R. <g4jc@openmailbox.org>

pkgname=webkit2gtk
pkgver=2.17.2
pkgrel=2.nonprism1
pkgdesc="GTK+ Web content engine library, without geoclue2 support"
arch=(i686 x86_64)
url="https://webkitgtk.org/"
license=(custom)
depends=(libxt libxslt enchant libsoup gst-plugins-base-libs
         libsecret libwebp harfbuzz-icu gtk3 libnotify hyphen)
makedepends=(gtk2 gperf gobject-introspection ruby gtk-doc cmake python python2)
optdepends=('gtk2: Netscape plugin support'
            'gst-plugins-base: free media decoding'
            'gst-plugins-good: media decoding'
            'gst-libav: nonfree media decoding')
options=(!emptydirs)
source=("https://webkitgtk.org/releases/webkitgtk-${pkgver}.tar.xz" #{,.sig}
        'icu59.patch')
sha256sums=('7ad9d11fe247100f476fc70bc9e425306cf56aa97b399dce52964493a9c666e0'
            'SKIP')
validpgpkeys=('D7FCF61CF9A2DEAB31D81BD3F3D322D0EC4582C3')

prepare() {
  mkdir build

  cd webkitgtk-$pkgver
  sed -i '1s/python$/&2/' Tools/gtk/generate-gtkdoc
  rm -r Source/ThirdParty/gtest/
  #rm -r Source/ThirdParty/qunit/
  patch -Np1 -i ../icu59.patch
}

build() {
  cd build
  cmake -DPORT=GTK -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_SKIP_RPATH=ON -DCMAKE_INSTALL_PREFIX=/usr \
        -DLIB_INSTALL_DIR=/usr/lib -DLIBEXEC_INSTALL_DIR=/usr/lib/webkit2gtk-4.0 \
        -DUSE_GEOCLUE2=OFF -DENABLE_GEOLOCATION=OFF \
        -DENABLE_GTKDOC=ON -DPYTHON_EXECUTABLE=/usr/bin/python2 ../webkitgtk-$pkgver
  if [[ "$CARCH" =~ ^arm*|^aarch64$ ]]; then
    # strip -O3 from cmake generated makefiles
    find ./ -type f -exec sed -i -e 's/-O3//g' {} \;
  fi
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install

  install -m755 -d "$pkgdir/usr/share/licenses/webkit2gtk"
  cd "$srcdir/webkitgtk-$pkgver/Source"
  for f in $(find -name 'COPYING*' -or -name 'LICENSE*'); do
    echo $f >> "$pkgdir/usr/share/licenses/webkit2gtk/LICENSE"
    cat $f >> "$pkgdir/usr/share/licenses/webkit2gtk/LICENSE"
    echo "" >> "$pkgdir/usr/share/licenses/webkit2gtk/LICENSE"
  done
}