# $Id: PKGBUILD 174361 2016-05-08 17:07:58Z arojas $
# Maintainer (Arch): speps <speps at aur dot archlinux dot org>
# Contributor (Arch): Alexander Fehr <pizzapunk gmail com>
# Contributor (Arch): dorphell <dorphell@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Aditya Som <icarious@hacari.org>"

pkgname=sylpheed
pkgver=3.5.0
pkgrel=3.nonprism1
pkgdesc="Lightweight and user-friendly e-mail client, without Gmail support"
arch=('i686' 'x86_64')
url="http://sylpheed.sraoss.jp/en/"
license=('GPL')
replaces=(${pkgname}-nonprism)
conflicts=(${pkgname}-nonprism)
depends=('compface' 'gpgme' 'gtkspell' 'desktop-file-utils')
makedepends=('openssl')
source=("http://sylpheed.sraoss.jp/$pkgname/v${pkgver%.*}/$pkgname-$pkgver.tar.bz2"
        'nonprism.patch')
md5sums=('289cdd2bef00dd5f17fa90def1cc9d81'
         'e1bddc14962e607cdb899ec082660639')

prepare() {
  cd $pkgname-$pkgver

  # Remove Gmail support
  patch -Np1 -i "$srcdir/nonprism.patch"
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr \
              --enable-ldap
  make

  # Build Attachment-Tool Plug-in
  cd plugin/attachment_tool && make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir/" install

  # Install Attachment-Tool Plug-in
  cd plugin/attachment_tool
  make DESTDIR="$pkgdir/" install-plugin
}